executing multiple commands by taking user input windows terminal

Question

I want to run a bat file, in which I have two commands to execute sequentially.

@echo off
::taking version no. as input
set /p productVersion="Enter new product version: "
::executing first command
mvn versions:set -DnewVersion=%productVersion% && set /p commitChanges="new version is set for all modules %productVersion% Do you want commit your changes for all pom files :(y/n)" && call:commitChanges %commitChanges%
EXIT /B
::executing second command, after taking input y/n
:commitChanges
If %~1=="y" goto yes
If %~1=="n" goto no
If %~1=="Y" goto yes
If %~1=="N" goto no
EXIT /B
:no
mvn versions:revert
EXIT /B
:yes
mvn versions:commit
EXIT /B

first command executes successfully and line taking input for second command comes,but terminal gets closed and second command is not executed.

Compo · Accepted Answer · 2017-01-30 10:14:21Z

2

You may be better off using an else clause:

@Echo Off
:AskFirst
Set/P "productVersion=Enter new product version: "
If "%productVersion%"=="" GoTo AskFirst
Call mvn versions:set -DnewVersion=%productVersion%
Echo=new version is set for all modules %productVersion%
:AskSecond
Set/P "commitChanges=Do you want commit your changes for all pom files :(y/n) "
If /I "%commitChanges%"=="y" (Call mvn versions:commit) Else (
   If /I "%commitChanges%"=="n" (Call mvn versions:revert) Else (
      GoTo AskSecond))
Echo=changes have been committed
Pause
Exit/B

answered Jan 30, 2017 at 10:14

Compo

39k5 gold badges32 silver badges46 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Magoo · Accepted Answer · 2017-01-30 04:21:59Z

0

An EXIT /B instruction exits from the current routine, hence the routine will be exited once mvn versions:set -Dne... has ended.

answered Jan 30, 2017 at 4:21

Magoo

80.8k8 gold badges68 silver badges92 bronze badges

7 Comments

akash777.sharma Over a year ago

even if I remove all EXIT /B , it is still not working

Magoo Over a year ago

What is mvn? If mvn is a batch file (mvn.bat) then you need call mvn in order to have batch return to the procedure after completing mvn.

akash777.sharma Over a year ago

I removed EXIT /B and applied call before mvn command. first command executed and second input statement prompted but after entering a key, it showed an error : goto was unexpected at this time.

Magoo Over a year ago

%~1 refers to the first parameter provided to the batch file. You need (eg) if "%commitChanges%"=="y" .... note that if /i... will perform a case-insensitive comparison.

akash777.sharma Over a year ago

@echo off set /p productVersion="Enter new product version: " call mvn versions:set -DnewVersion=%productVersion% && set /p commitChanges="new version is set for all modules %productVersion% Do you want commit your changes for all pom files :(y/n)" && call:commitChanges %commitChanges% :commitChanges If "%commitChanges%"=="y" ( mvn versions:commit ) IF "%commitChanges%"=="n" ( mvn versions:revert ) IF "%commitChanges%"=="Y" ( mvn versions:commit ) IF "%commitChanges%"=="N" ( mvn versions:revert )

|

Collectives™ on Stack Overflow

executing multiple commands by taking user input windows terminal

2 Answers 2

Comments

7 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

7 Comments

Your Answer

Sign up or log in

Post as a guest

Related