Enumerate over a sequence in Clojure?

Question

In Python I can do this:

animals = ['dog', 'cat', 'bird']
for i, animal in enumerate(animals):
    print i, animal

Which outputs:

0 dog
1 cat
2 bird

How would I accomplish the same thing in Clojure? I considered using a list comprehension like this:

(println
  (let [animals ["dog" "cat" "bird"]]
    (for [i (range (count animals))
          animal animals]
      (format "%d %d\n" i animal))))

But this prints out every combination of number and animal. I'm guessing there is a simple and elegant way to do this but I'm not seeing it.

kotarak · Accepted Answer · 2010-11-16 17:08:30Z

47

There is map-indexed in core as of 1.2.

Your example would be:

(doseq [[i animal] (map-indexed vector ["dog" "cat" "bird"])]
  (println i animal))

answered Nov 16, 2010 at 17:08

kotarak

17.3k2 gold badges53 silver badges41 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Leonel · Accepted Answer · 2010-11-16 15:59:20Z

9

Quick solution:

(let [animals ["dog", "cat", "bird"]]
  (map vector (range) animals))

Or, if you want to wrap it in a function:

(defn enum [s]
  (map vector (range) s))

(doseq [[i animal] (enum ["dog", "cat", "bird"])]
  (println i animal))

What happens here is the function vector is applied to each element in both sequences, and the result is collected in a lazy collection.

Go ahead, try it in your repl.

answered Nov 16, 2010 at 15:59

Leonel

29.4k26 gold badges82 silver badges107 bronze badges

Comments

ordnungswidrig · Accepted Answer · 2010-11-16 16:21:06Z

8

Use indexed from clojure.contrib.seq:

Usage: (indexed s) Returns a lazy sequence of [index, item] pairs, where items come from 's' and indexes count up from zero.

(indexed '(a b c d)) => ([0 a] [1 b] [2 c] [3 d]

For your example this is

(require 'clojure.contrib.seq)
(doseq [[i animal] (clojure.contrib.seq/indexed ["dog", "cat", "bird"])]
  (println i animal))

edited Nov 16, 2010 at 16:21

answered Nov 16, 2010 at 16:12

ordnungswidrig

3,1971 gold badge19 silver badges29 bronze badges

3 Comments

Leonel Over a year ago

heh. Take a look at the source code for function indexed: github.com/clojure/clojure-contrib/blob/…

ordnungswidrig Over a year ago

heh. I know. I wonder why you named the function 'enum' in your example, then :-)

Indrajith Indraprastham Over a year ago

clojure-contrib is now deprecated

Community · Accepted Answer · 2017-05-23 12:00:27Z

5

map-indexed looks right but: Do we really need all of the doseq and deconstructing args stuff in the other answers?

(map-indexed println ["dog", "cat", "bird"])

EDIT: as noted by @gits this works in the REPL but doesn't respect that clojure is lazy by default. dorun seems to be the closest among doseq, doall and doseq for this. doseq, howver, seems to be the idiomatic favorite here.

(dorun (map-indexed println ["dog", "cat", "bird"]))

edited May 23, 2017 at 12:00

CommunityBot

11 silver badge

answered Mar 10, 2016 at 15:46

Phil Cooper

5,8871 gold badge27 silver badges41 bronze badges

2 Comments

glts Over a year ago

map-indexed returns a lazy seq. doseq is necessary to ensure side effects happen now, not later (in this case, the printing effected by println).

Phil Cooper Over a year ago

@git right and thanks, I noticed that but didn't update because I'm still learning and don't know if doseq is the real favorite idiom here.

glts · Accepted Answer · 2016-03-12 22:17:13Z

1

Yet another option is to use reduce-kv, which pairs the elements of a vector with their indexes.

Thus,

(reduce-kv #(println %2 %3) nil ["dog" "cat" "bird"])

or perhaps the slightly more explicit

(reduce-kv (fn [_ i animal] (println i animal)) nil ["dog" "cat" "bird"])

I wouldn’t pick this solution over the one with doseq here, but it is good to be aware of this specialisation for vectors in reduce-kv.

answered Mar 12, 2016 at 22:17

glts

23k12 gold badges80 silver badges94 bronze badges

Collectives™ on Stack Overflow

Enumerate over a sequence in Clojure?

5 Answers 5

Comments

Comments

3 Comments

2 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

5 Answers 5

Comments

Comments

3 Comments

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related