Using a string as variable name

Question

I have a dataset like this:

string_var | var1 | var2 | var3
var2       |  8   |   8  |  4
var3       |  7   |   5  |  7        
var2       |  10  |   10 |  5

I need to test whether var1 is equal to either var2 or var3, depending on the string that is contained in string_var. My problem is to convert these strings into variable names to do something like:

gen test=1 if var1==string_var

where, after the ==, I need some kind of conversion function to let Stata read the string e.g. var2 as the following:

gen test=1 if var1==var2

Nick Cox · Accepted Answer · 2017-05-02 10:04:22Z

1

With just two possibilities, you can branch on the choice. (With several possibilities, I think you'd need a loop.)

clear 
input str4 string_var  var1  var2  var3
var2         8      8    4
var3         7      5    7        
var2         10     10   5
end 

gen test = cond(string_var == "var2", var1 == var2, var1 == var3) 

list 

     +--------------------------------------+
     | string~r   var1   var2   var3   test |
     |--------------------------------------|
  1. |     var2      8      8      4      1 |
  2. |     var3      7      5      7      1 |
  3. |     var2     10     10      5      1 |
     +--------------------------------------+

EDIT:

Here is a more general solution. (If anyone else thinks of a neater solution, be sure to post.)

gen test = . 

levelsof string_var, local(names) 

quietly foreach name of local names { 
    replace test = var1 == `name' if string_var == "`name'" 
}

edited May 2, 2017 at 10:04

answered May 2, 2017 at 9:53

Nick Cox

37.4k6 gold badges37 silver badges51 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

CompSocialSciR Over a year ago

Yes I do have more then two choices, how would this translate into a loop?

CompSocialSciR Over a year ago

It works perfectly. I must admit I had never seen this replacing a variable directly with a tested condition. Thanks a lot.

Nick Cox Over a year ago

I haven't often seen this except in the context of row-wise operations in which people want e.g. the name of whichever variable contains the maximum (itself problematic whenever there are ties).

Collectives™ on Stack Overflow

Using a string as variable name

1 Answer 1

3 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

3 Comments

Your Answer

Sign up or log in

Post as a guest

Related