Regex match multiple pattern

(See comments below the question for the problem description.)

The data is in a multi-line string, with multiple sections starting with Object:. Within each there are multiple lines starting with phrases Page location: and Comments:. The rest of the line for all these need be captured, and all organized by Objects.

Instead of attempting a tortured multi-line "single" regex, break the string into lines and process section by section. This way the problem becomes a very simple one.

The results are stored in an array of hashrefs; each has for keys the shown phrases. Since they can appear more than once per section their values are arrayrefs (with what follows them on the line).

use warnings;
use strict;
use feature 'say';

my $input_string = '...'; 
my @lines = split /\n/, $input_string;

my $patt = qr/Object|Page location|Comments/;

my @sections;
for (@lines) 
{
    next if not /^\s*($patt):\s*(.*)/;

    push @sections, {}  if $1 eq 'Object';

    push @{ $sections[-1]->{$1} }, $2;
}

foreach my $sec (@sections) {
    foreach my $key (sort keys %$sec) {
        say "$key:";
        say "\t$_" for @{$sec->{$key}};
    }   
}

With the input string copied (suppressed above for brevity), the output is

Comments:
        Lorem ipsum dolor sit amet,  [...] 
        Lorem ipsum dolor sit amet,  [...]
Page location:
        SDEWRSD3242SD-234/324/234 (1)
        SDEWRSD3242SD-SDF/234/324 (5)
Object:
        TLE-234DSDSDS324-234SDF324ER

A few comments.

Once the Object line is found we add a new hashref to @sections. Then the match for a pattern is set as a key and the rest of its line added to its arrayref value. This is done for the current (so last) element of @sections.

This adds an empty string if a pattern had nothing following. To disallow add next if not $2;

Note. An easy and common way to print complex data structures is via the core module Data::Dumper. But also see Data::Dump for a much more compact printout.