How do I encode HTTP GET query strings in Perl?

Question

This question is somewhat related to What’s the simplest way to make a HTTP GET request in Perl?.

Before making the request via LWP::Simple I have a hash of query string components that I need to serialize/escape. What's the best way to encode the query string? It should take into account spaces and all the characters that need to be escaped in valid URIs. I figure it's probably in an existing package, but I'm not sure how to go about finding it.

use LWP::Simple;
my $base_uri = 'http://example.com/rest_api/';
my %query_hash = (spam => 'eggs', foo => 'bar baz');
my $query_string = urlencode(query_hash); # Part in question.
my $query_uri = "$base_uri?$query_string";
# http://example.com/rest_api/?spam=eggs&foo=bar+baz
$contents = get($query_uri);

Toby Speight · Accepted Answer · 2025-07-24 12:00:18Z

31

URI::Escape is probably the most direct answer, as other have given, but I would recommend using a URI object for the entire thing. URI automatically escapes the GET parameters for you (using URI::Escape).

my $uri = URI->new( 'http://example.com' );
$uri->query_form(foo => '1 2', bar => 2);
print $uri; ## http://example.com?foo=1+2&bar=2

As an added bonus, LWP::Simple's get() function will take a URI object as its argument instead of a string.

edited Jul 24 at 12:00

Toby Speight

32.1k58 gold badges82 silver badges117 bronze badges

answered Jan 16, 2009 at 2:41

gpojd

23.2k8 gold badges45 silver badges71 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

brian d foy · Accepted Answer · 2025-07-25 00:39:35Z

17

URI::Escape does what you want.

use URI::Escape;

sub escape_hash {
    my %hash = @_;
    my @pairs;
    for my $key (keys %hash) {
        push @pairs, join "=", map { uri_escape($_) } $key, $hash{$key};
    }
    return join "&", @pairs;
}

edited Jul 25 at 0:39

brian d foy

134k31 gold badges214 silver badges613 bronze badges

answered Jan 16, 2009 at 1:29

Leon Timmermans

30.3k2 gold badges65 silver badges111 bronze badges

3 Comments

Hynek -Pichi- Vychodil Over a year ago

Shortly: sub escape_hash{my %h = @_; return join '&', map{join '=', map uri_escape($_), $_, $h{$_}} keys %h}

Leon Timmermans Over a year ago

I though of doing that too, but nesting maps just didn't look right to me.

Hynek -Pichi- Vychodil Over a year ago

Map inside for(each) with push sounds same complicated for me but it introduce unneeded temporary variable.

user699082 · Accepted Answer · 2014-04-03 16:48:58Z

6

URI is far simpler than URI::Escape for this. The method query_form() accepts a hash or a hashref:

use URI;
my $full_url = URI->new('http://example.com');
$full_url->query_form({"id" => 27, "order" => "my key"});
print "$full_url\n";     # http://example.com?id=27&order=my+key

answered Apr 3, 2014 at 16:48

user699082

Comments

Flimm · Accepted Answer · 2015-01-16 11:10:24Z

6

Use the module URI to build the URL with the query parameters:

use LWP::Simple;
use URI;

my $uri_object = URI->new('http://example.com/rest_api/');
$uri_object->query_form(spam => 'eggs', foo => 'bar baz');

$contents = get("$uri_object");

I found this solution here.

answered Jan 16, 2015 at 11:10

Flimm

154k49 gold badges282 silver badges295 bronze badges

1 Comment

bbarker Over a year ago

Although solutions using map and URI::Escape are elegant ... this seems simplest and thus best to me.

Josh · Accepted Answer · 2014-04-05 21:10:10Z

1

URI::Escape is the module you are probably thinking of.

edited Apr 5, 2014 at 21:10

Josh

13.6k4 gold badges52 silver badges50 bronze badges

answered Jan 16, 2009 at 1:32

SquareCog

19.7k8 gold badges52 silver badges63 bronze badges

Collectives™ on Stack Overflow

How do I encode HTTP GET query strings in Perl?

5 Answers 5

Comments

3 Comments

Comments

1 Comment

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

5 Answers 5

Comments

3 Comments

Comments

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related