Updating a nested map within a vector within a map

Question

I have a map within a vector within a map.

{ :label "Apparel & Accessories", 
  :img_class "itm_3", 
  :children [
             {:id "sub1", 
              :label "Clothing", 
              :markup [:div] 
             } 
             {:id "sub2", 
              :label "Shoes & Footwear", 
              :markup [:div] 
             } 
   ] 
}  `

What I want to do is dissoc the key :markup from all entries. I've been struggling with this for 2 hours. Only far I got is dissoc the key :children. But the requirement is to remove :markup key only.

So final output should be

{ :label "Apparel & Accessories", 
  :img_class "itm_3", 
  :children [
             {:id "sub1", 
              :label "Clothing", 
             } 
             {:id "sub2", 
              :label "Shoes & Footwear", 
             } 
   ]
}   `

Any contribution is highly appreciated.

You might want to consider Specter, which does what you want in one line of code: github.com/nathanmarz/specter#specter- — bfontaine
– bfontaine, Commented Sep 5, 2017 at 8:33

Chris Murphy · Accepted Answer · 2017-09-04 18:28:19Z

2

It is a good habit to make the alteration 'all in one go':

(update m :children (fn [v] (assert (vector? v)) (mapv #(dissoc % :markup) v)))

Here m is only being referred to once. It would matter for instance if you were doing a swap!.

If you don't have a vector, yet want to create one on the fly then this will work:

(update m :children (fn [xs]
                      (->> xs
                           vec
                           (mapv #(dissoc % :markup)))))

But on the other hand there is no real need to be using vectors. The original solution without the assert works fine when :children is set to:

'({:id    "sub1",
  :label  "Clothing",
  :markup [:div]}
 {:id     "sub2",
  :label  "Shoes & Footwear",
  :markup [:div]})

edited Sep 4, 2017 at 18:28

answered Sep 4, 2017 at 17:50

Chris Murphy

6,5092 gold badges27 silver badges46 bronze badges

Sign up to request clarification or add additional context in comments.

8 Comments

Dan Jay Over a year ago

I think my map is Lazy. With your solution I get an error "ClassCastException clojure.lang.LazySeq cannot be cast to clojure.lang.Associative"

Dan Jay Over a year ago

AssertionError Assert failed: (vector? v)

Chris Murphy Over a year ago

So your data is different to that in your question. You can use into [] to change your data. But I'll take out the assert and make it work locally...

Dan Jay Over a year ago

Data not much different but bigger. Some has many data within :children some has nil.

Chris Murphy Over a year ago

By the way a map can't be lazy. I think the problem is that where you think there are maps there are really seqs.

|

swlkr · Accepted Answer · 2017-09-04 19:37:11Z

1

I solved it in two steps, not one unfortunately.

(def m { :label "Apparel & Accessories", :img_class "itm_3", :children [ {:id "sub1", :label "Clothing", :markup [:div] } {:id "sub2", :label "Shoes & Footwear", :markup [:div] } ] })

(defn dissoc-markup [child]
  (dissoc child :markup))

(update m :children #(mapv dissoc-markup %))

answered Sep 4, 2017 at 19:37

swlkr

3105 silver badges11 bronze badges

Comments

Alfred Xiao · Accepted Answer · 2017-09-07 03:30:36Z

1

If you are sure that you want to remove :markup whenever you see it, here is a simple way to do it:

(def your-data {:your-data "...."})
(clojure.walk/postwalk (fn [m] 
                         (if (map? m) 
                           (dissoc m :markup) 
                           m))
                       your-data)

answered Sep 7, 2017 at 3:30

Alfred Xiao

1,78815 silver badges16 bronze badges

Comments

Chris · Accepted Answer · 2017-09-04 17:46:34Z

0

If your initial map is m, a possible solution is this

(assoc m :children (mapv #(dissoc % :markup) (m :children)))

It takes the value of :children, removes the :markup keys and replaces the result to the initial map.

edited Sep 4, 2017 at 17:46

answered Sep 4, 2017 at 17:38

Chris

234 bronze badges

1 Comment

Dan Jay Over a year ago

I get an error "ClassCastException clojure.lang.LazySeq cannot be cast to clojure.lang.IFn"

Collectives™ on Stack Overflow

Updating a nested map within a vector within a map

4 Answers 4

8 Comments

Comments

Comments

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

4 Answers 4

8 Comments

Comments

Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related