Excel VBA - Code to open MS Project File not working

Question

I wrote some code to allow me to select an MS Project file and open it, however when I run the code, nothing happens.

Zero errors, it just exits, any suggestions with what i'm doing wrong here?

Code below

Sub START()

' MS Project variables 
Dim Proj             As MSProject.Application
Dim NewProj          As MSProject.Project

'File Name Variables
Dim FileOpenType     As Variant
Dim NewProjFileName  As String
Dim NewProjFilePath  As String
Dim NewProjFinal     As String


'Code to find and open project files
Set Proj = CreateObject("MsProject.Application")
MsgBox ("Please Select MS Project File for Quality Checking")

'Select Project File
FileOpenType = Application.GetOpenFilename( _
               FileFilter:="MS Project Files (*.mpp), *.mpp", _
               Title:="Select MS Project file", _
               MultiSelect:=False)

'Detect if File is selected, if not then stop code

If FileOpenType = False Then
   MsgBox ("You Havent Selected a File")
   GoTo EndPoint
End If

'Write the FileOpenType variant to two separate strings
NewProjFilePath = Left$(FileOpenType, InStrRev(FileOpenType, "\"))
NewProjFileName = Mid$(FileOpenType, InStrRev(FileOpenType, "\") + 1)

'Open Project File
Proj.FileOpen NewProjFilePath & NewProjFileName


EndPoint:
End Sub

@PootyToot please don;t modify your code with the answer, this disables other users in the future to understand what was issue to begin with, and how it was resolved. — Shai Rado
– Shai Rado, Commented Oct 25, 2017 at 5:12

Shai Rado · Accepted Answer · 2017-10-25 05:25:34Z

Just a couple of notes:

First, since you are using Early Binding to refer to MS-Project, so instead of setting Set Proj = CreateObject("MsProject.Application"), which is used for Late Binding, you can use Set Proj = New MSProject.Application.

Second: since Proj is defined as MSProject.Application, in order to make the MS-Project application visible, it's enough to use Proj.Visible = True.

Code

Option Explicit

Sub START()

' MS Project variables

Dim Proj             As MSProject.Application
Dim NewProj          As MSProject.Project

'File Name Variables
Dim FileOpenType     As Variant
Dim NewProjFileName  As String
Dim NewProjFilePath  As String
Dim NewProjFinal     As String

Set Proj = New MSProject.Application ' since you are using Early binding, you can use this type of setting a new MS-Project instance

MsgBox "Please Select MS Project File for Quality Checking"

'Select Project File
FileOpenType = Application.GetOpenFilename( _
               FileFilter:="MS Project Files (*.mpp), *.mpp", _
               Title:="Select MS Project file", _
               MultiSelect:=False)

If FileOpenType = False Then
   MsgBox "You Havent Selected a File"
   Exit Sub ' <-- use Exit Sub instead of GoTo EndPoint
End If

'Write the FileOpenType variant to two separate strings
NewProjFilePath = Left$(FileOpenType, InStrRev(FileOpenType, "\"))
NewProjFileName = Mid$(FileOpenType, InStrRev(FileOpenType, "\") + 1)

'Open Project File
Proj.FileOpen NewProjFilePath & NewProjFileName

Proj.Visible = True ' <-- Set MS-Project as visible application

End Sub

PootyToot · Accepted Answer · 2017-10-25 04:08:38Z

0

Resolved by adding the following line, edited code to show

Proj.Application.Visible = True

answered Oct 25, 2017 at 4:08

PootyToot

3492 gold badges11 silver badges28 bronze badges

Collectives™ on Stack Overflow

Excel VBA - Code to open MS Project File not working

2 Answers 2

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related