XML Namespace in Delphi

You are passing an IXMLNode interface pointer to ShowMessage(), which expects a string instead. So presumably, in your real code, you have actually done ShowMessage(Node.ChildNodes['Cube'].NodeName); instead.

Which indeed reports 'gesmes:Cube', which is not what you are expecting. The Cube you want is in the http://www.ecb.int/vocabulary/2002-08-01/eurofxref namespace, which is different than the namespace of its parent Envelope (http://www.gesmes.org/xml/2002-08-01). So what actually happens is that DocumentElement.ChildNodes['Cube'] tries to find a Cube in the Envelope's namespace, finds no such element, so TXMLDocument creates a new one because the doNodeAutoCreate flag is enabled by default in the Doc.Options property. That is the Cube that DocumentElement.ChildNodes['Cube'] returns, not the Cube you want.

Because the Envelope and its immediate Cube child are in different namespaces, you can't use ChildNodes['Cube'] on the DocumentElement, you have to use ChildNodes.FindNode() instead, specifying the Cube's actual namespace:

Node := Doc.DocumentElement;
Node := Node.ChildNodes.FindNode('Cube', 'http://www.ecb.int/vocabulary/2002-08-01/eurofxref');

The next Cube is in the same namespace as its parent Cube, so you can use ChildNodes['Cube'] to get it:

Node := Node.ChildNodes['Cube'];

Then you can access the time attribute, if needed:

Node.Attributes['time']

And loop through the remaining child Cubes:

Node := Node.ChildNodes.First;
while Node <> nil do
begin
  if Node.LocalName = 'Cube' then
  begin
    // use Node.Attributes['currency'] and Node.Attributes['rate'] as needed...
  end;
  Node := Node.NextSibling;
end;

Here is the complete code:

procedure TForm2.Button1Click(Sender: TObject);
var
  Doc: IXMLDocument;
  Node: IXMLNode;
  sl: TStringList;
begin
  sl := TStringList.Create;
  try
    Doc := LoadXMLDocument('C:\Users\Kevin\Desktop\test.xml');
    try
      Node := Doc.DocumentElement;
      if Node = nil then ... // handle the error as needed...

      Node := Node.ChildNodes.FindNode('Cube', 'http://www.ecb.int/vocabulary/2002-08-01/eurofxref');
      if Node = nil then ... // handle the error as needed...

      Node := Node.ChildNodes['Cube'];
      if Node = nil then ... // handle the error as needed...

      Node := Node.ChildNodes.First;
      while Node <> nil do
      begin
        if Node.LocalName = 'Cube' then
          sl.Add(Node.Attributes['currency'] + '=' + Node.Attributes['rate']);
        Node := Node.NextSibling;
      end;
    finally
      Node := nil;
      Doc := nil;
    end;

    // use sl as needed...

  finally
    sl.Free;
  end;
end;