Idiomatic clojure question on sequence transformation

Question

I am learning Clojure, and I need a push in the right direction with this problem I came up with.

I have a sequence of events. Each event includes a 'date'.

(def events
  [
   [1509 :marry   "Catherine of Aragon"]
   [1527 :unmarry "Catherine of Aragon"]
   [1533 :marry   "Anne Boleyn"]
   [1536 :unmarry "Anne Boleyn"]
   [1536 :marry   "Jane Seymour"]
   [1537 :unmarry "Jane Seymour"]
   [1540 :marry   "Anne of Cleves"]
   [1540 :unmarry "Anne of Cleves"]
   [1540 :marry   "Catherine Howard"]
   [1542 :unmarry "Catherine Howard"]
   [1543 :marry   "Catherine Parr"]])

I want to convert this into a lazy timeline, i.e. a sequence containing one vector per year. Starting with the year of the first event, and continuing to infinity.

[[[:marry "Catherine of Aragon"]] [] [] [] [] [] [] [] [] [] [] [] [] [] [] [] [] [] [[:unmarry "Catherine of Aragon"]] [] [] [] [] [] [[:marry "Ane Boleyn"]] [] [] [[:unmarry "Anne Boleyn"] [:marry "Jayne Seymour"]] ...]

I'd consider re-formatting to adhere to lisp/clojure convention of putting the trailing parens on one line, see: techbehindtech.com/2010/12/09/clojure-good-coding-guidelines — 0x89
– 0x89, Commented Jan 31, 2011 at 14:18

cgrand · Accepted Answer · 2011-01-31 13:34:45Z

8

(def timeline
  (let [events-by-year (group-by first events)]
    (map #(map next (events-by-year %))
      (iterate inc (reduce min (keys events-by-year))))))

Quick test:

=> (take 30 timeline)
(((:marry "Catherine of Aragon")) () () () () () () () () () () () () () () () ()
 () ((:unmarry "Catherine of Aragon")) () () () () () ((:marry "Anne Boleyn")) ()
 () ((:unmarry "Anne Boleyn") (:marry "Jane Seymour")) ((:unmarry "Jane Seymour"))
 ())

answered Jan 31, 2011 at 13:34

cgrand

7,95930 silver badges32 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

j-g-faustus · Accepted Answer · 2011-01-31 16:01:55Z

3

I would suggest something like:

(defn timeline
  ([] (timeline (ffirst *events*) *events*))
  ([time evts]
     (let [[now later] (split-with #(= time (first %)) evts)]
       (cons (map rest now)
             (lazy-seq (timeline (inc time) later))))))

Test:

user> (take 30 (timeline))
(((:marry "Catherine of Aragon")) () () () () () () () () () () () () () () () () () 
 ((:unmarry "Catherine of Aragon")) () () () () () ((:marry "Anne Boleyn")) () () 
 ((:unmarry "Anne Boleyn") (:marry "Jane Seymour")) ((:unmarry "Jane Seymour")) ())

I'm assuming that the list of events is infinite as well :)

Updated with improvements, and borrowing a couple of ideas from cgrand (thanks :)

edited Jan 31, 2011 at 16:01

answered Jan 31, 2011 at 12:40

j-g-faustus

9,0574 gold badges35 silver badges42 bronze badges

2 Comments

GHZ Over a year ago

Thanks. It breaks when there are more than one event on the same date i.e. [1515 :c] [1515 :d]. However, there are a lot of good pointers in there, so maybe I can figure the rest out myself.

j-g-faustus Over a year ago

@GHZ Ah, missed that. Well, cgrand's was nicer anyway :) Refactored, leaving as a second option.

Collectives™ on Stack Overflow

Idiomatic clojure question on sequence transformation

2 Answers 2

Comments

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related