check for spaces in file name inside of for loop in batch file

Question

I have a batch script that is calling a VBscript file. It reiterates through all files in a watched folder.

It needs to verify if the file name has spaces in it and if so reject the file and not process it with the VBS.

I must have an error on the code as I get the error message:

ELSE was not expected at this time.

I have looked at the documentation and searched for the answer for quite some time, including this question: check "IF" condition inside FOR loop (batch/cmd)

But still, I can't see what is wrong in my syntax:

@ECHO OFF
setlocal ENABLEDELAYEDEXPANSION
call :ReadIni Infolder inFolder 
call :ReadIni Outfolder outFolder 

echo %inFolder%
echo %outFolder%

pause

:StartLoop
FOR %%I in (%inFolder%\*.srt) DO (
  ECHO %%I
  ECHO %%~nxI
  SET TESTNAME=%%~nxI
  ECHO !TESTNAME!
  ECHO !TESTNAME: =_!
  PAUSE
  IF NOT !TESTNAME!==!TESTNAME: =_! (
    move "%~sdp0%%~nxI" "%outFolder%\ERROR_IN_FILE_NAME_%%~nxI"
  ) ELSE (
    copy /y "%%I" "%~sdp0%%~nxI"
    %~sdp0SRToffset.vbs "%~sdp0%%~nxI" "%~sdp0%%~nxI"
    IF %ERRORLEVEL%==1 (
      Goto StartLoop
    ) else (
      move "%~sdp0%%~nxI" "%outFolder%\"
      move "%~sdp0QC_%%~nxI" "%outFolder%\"
      del "%%I"
    )
  )
)
timeout /t 1
goto StartLoop

:ReadIni
FOR /F "tokens=2 delims==" %%a in ('find "%~1=" config.ini') do set %~2=%%a
exit /b

Any help would be appreciated.

ib11 · Accepted Answer · 2018-02-16 19:48:30Z

2

IF NOT "!TESTNAME!"=="!TESTNAME: =_!" (

 ...

IF %ERRORLEVEL%==1 (

Quoting the strings causes cmd to regard the string as a single entity.

Note that the following if %errorlevel% will be executed using the value of errorlevel at :startloop. (See delayed expansion for reasoning.)

Cure by using if !errorlevel!==1 (. (Using the runtime value of errorlevel as established by the vbs routine.)

edited Feb 16, 2018 at 19:48

ib11

2,5584 gold badges26 silver badges56 bronze badges

answered Feb 16, 2018 at 17:05

Magoo

80.8k8 gold badges68 silver badges92 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

ib11 Over a year ago

Thanks. I just figured it out, too. This is what I ended up using IF "!TESTNAME!" NEQ "!TESTNAME: =_!" ( and thanks for pointing out the error in errorlevel. I changed it to IF ERRORLEVEL 1 (

Collectives™ on Stack Overflow

check for spaces in file name inside of for loop in batch file

1 Answer 1

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related