Call series of Java static methods from Clojure

Question

Let's say I have come across a class with several static setter methods that I'd like to call in a row. The functionality I'm looking for is similar to that provided by doto, except that it must work on a class instead of an object:

(doto MyClass
      (setA "a")
      (setB "b"))

Unfortunately, when I try this, I get RuntimeException: Unable to resolve symbol: setA. Is there a special doto macro for classes?

user12341234 · Accepted Answer · 2018-04-02 14:00:28Z

2

I will leave this question open, since I'm hoping there's a better answer, but here's my home-grown macro to solve this problem:

(defmacro doto-class
  "Calls a series of static methods on a class"
  [klass & forms]
  (cons 'do
        (for [f forms]
          `(. ~klass ~f))))

which expands the example:

(macroexpand-1
 '(doto-class MyClass
              (setA "a")
              (setB "b")))

to

(do (. MyClass (setA "a"))
    (. MyClass (setB "b")))

edited Apr 2, 2018 at 14:00

answered Mar 31, 2018 at 17:20

user12341234

7,2836 gold badges27 silver badges52 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Carcigenicate Over a year ago

My brains fried from work, but I couldn't come up with anything, and the macro I wrote basically ended up looking like yours. I suspect this is such a rare use case that it wasn't considered. I don't think I've ever needed to sequence calls to a static method.

Thumbnail · Accepted Answer · 2018-04-01 01:03:53Z

1

How do you call a static Java method from Clojure? Like this ...

(Classname/staticMethod args*)

For example,

> (System/getProperty "java.vm.version")

=> "25.141-b15"

We want a macro, say doto-static, that re-arranges this from (doto-static System (getProperty "java.vm.version")), and also allows a chain of calls.

Such a macro is ...

(defmacro doto-static [class-symbol & calls]
  (let [qualify (fn [method-symbol] (->> method-symbol
                                    (name)
                                    (str (name class-symbol) \/)
                                  (symbol)))
        elaborate (fn [[method-symbol & arg-exprs]]
                      (cons (qualify method-symbol) arg-exprs))]
          (cons 'do (map elaborate calls))))

For example,

> (doto-static System (getProperty "java.vm.version") (getProperty "java.vm.version"))

=> "25.141-b15"

answered Apr 1, 2018 at 1:03

Thumbnail

13.5k2 gold badges31 silver badges39 bronze badges

2 Comments

user12341234 Over a year ago

Interesting! Do you know if this macro provides benefits over the naive solution I posted earlier? If so, that'd make a great addition to this answer.

Thumbnail Over a year ago

@user12341234 Yours is cleaner. The only advantage this possesses is to conform to the preferred syntax for static calls to Java. I hadn't got the point of your answer, or I wouldn't have posted this one.

Collectives™ on Stack Overflow

Call series of Java static methods from Clojure

2 Answers 2

1 Comment

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related