how to pass variable from PowerShell to batch variable

Question

I call the powershell command in batch and want to save the $tmpVersion to batch variable "version".

set version = powershell.exe -Command "$tmpVersion = (Get-ItemProperty 'HKLM:\Software\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\myapp').DisplayVersion;"

Have you tried anything? Like, remove $tmpVersion = , or add $tmpVersion to the very end? — Mathias R. Jessen
– Mathias R. Jessen, Commented Apr 30, 2018 at 15:39
for /F "delims=" %%a in ('powershell.exe etc...') do set "version=%%a", but you need to also remove the $tmpVersion = part... — Aacini
– Aacini, Commented Apr 30, 2018 at 15:41
Don't use a batch file in the first place. Write the script in PowerShell. — Bill_Stewart
– Bill_Stewart, Commented Apr 30, 2018 at 16:08
Why not just use Reg.exe for this instead of a hybrid batch/script? — user6811411
– user6811411, Commented Apr 30, 2018 at 16:19

Compo · Accepted Answer · 2018-04-30 17:43:36Z

You can use a For loop to save the result of a command as a variable:

powershell.exe example:

@Echo Off
Set "RegRoot=HKLM"
Set "RegKey=SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\myapp"
Set "RegVal=DisplayVersion"
Set "Version="
For /F %%A In (
    'PowerShell -NoP -NoL "(GP '%RegRoot%:%RegKey%').%RegVal%" 2^>Nul'
) Do Set "Version=%%A"
If Not Defined Version Exit /B
Echo %Version%
Pause

reg.exe example:

@Echo Off
Set "RegRoot=HKLM"
Set "RegKey=SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\myapp"
Set "RegVal=DisplayVersion"
Set "Version="
For /F "Tokens=2*" %%A In ('Reg Query "%RegRoot%\%RegKey%" /V "%RegVal%" 2^>Nul'
) Do Set "Version=%%B"
If Not Defined Version Exit /B
Echo %Version%
Pause

WMIC.exe example:

@Echo Off
Set "RegRoot=&H80000002"
Set "RegKey=SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\myapp"
Set "RegVal=DisplayVersion"
Set "Version="
For /F Tokens^=2Delims^=^" %%A In ('WMIC Class StdRegProv
     Call GetStringValue hDefKey^="%RegRoot%" sSubKeyName^="%RegKey%"
      sValueName^="%RegVal%" 2^>Nul') Do Set "Version=%%A"
If Not Defined Version Exit /B
Echo %Version%
Pause

Collectives™ on Stack Overflow

how to pass variable from PowerShell to batch variable

1 Answer 1

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related