replace values in two columns using awk

Question

Hi I have a text file that look like this

P383      0         II-5    2     0     1/2   0       0       42.7    0       54.67   0      
T528      0         P383    2     0     1/2   0       0       0       0       34.06   0      
T529      III-8     0       2     0     0     0       0       0       0       37.74   0      
T530      III-8     0       2     0     0     0       0       0       0       36.73   0      
3B888     III-4     III-5   2     0     1/2   38.4    0       0       0       44.38   0

I want to replace the 0 in columns 2, 3 and 5 with " " (a blank), I know how to do it for one column

The desired output would be

P383                II-5    2           1/2   0       0       42.7    0       54.67   0      
T528                P383    2           1/2   0       0       0       0       34.06   0      
T529      III-8             2           0     0       0       0       0       37.74   0      
T530      III-8             2           0     0       0       0       0       36.73   0      
3B888     III-4     III-5   2           1/2   38.4    0       0       0       44.38   0

I know how to do it for a single column

 awk '$3=="0"{$3=" "}; {print}' file

But how I do it for the three columns at the same time?

Thanks

thanks @JNevill, but this command awk '$2=="0" ; $3=="0" ; $5=="0" {$2=" ";$3=" ";$5=" "; print}' file does not produce the desired output, could you elaborate the answer please? — user2380782
– user2380782, Commented May 14, 2018 at 16:36

RavinderSingh13 · Accepted Answer · 2018-05-14 17:28:04Z

2

Following awk may help you on same.

awk '{$2=$2==0?"":$2;$3=$3==0?"":$3;$5=$5==0?"":$5;} 1' OFS="\t"  Input_file

Solution 2nd: Adding a more generic solution by which you could pass number of fields in function as follows.

awk '
function check_fields(a){
  num=split(a,array,",");
  for(i=1;i<=num;i++){
    $array[i]=$array[i]==0?"":$array[i]}
}
check_fields("2,3,5")
1
' OFS="\t"   Input_file

edited May 14, 2018 at 17:28

answered May 14, 2018 at 16:38

RavinderSingh13

135k14 gold badges61 silver badges100 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Ed Morton · Accepted Answer · 2018-05-14 17:34:37Z

0

awk '
    BEGIN { split("2 3 5", tmp); for (i in tmp) flds[tmp[i]] }
    { for (i in flds) if ($i == 0) $i = ""; print }
' file

answered May 14, 2018 at 17:34

Ed Morton

209k18 gold badges90 silver badges212 bronze badges

Collectives™ on Stack Overflow

replace values in two columns using awk

2 Answers 2

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related