Another simple Perl question...(hash to an array of objects)

Question

I'm working on creating a Graph class in Perl and I'm hoping to have each Graph contain Nodes. Each Node has some properties and also (for now) an array which contains references to each other node it is connected to. So far I have this definition of a node:

use strict; package Node;

sub new{
my $class = shift;
my @array = ();
my $array_r = \@array;
my $self = {
    code => undef,
name => undef,
country => undef,
continent => undef,
timezone => undef,
coordinates => undef
population => undef,
region => undef,
arrayRef => $array_r,
@_,

}; bless $self, $class; return $self; } Yet upon calling the following function from my main script:

sub getSetArray{
    my $self = shift;
my $param = shift;
my $temp = $self->{arrayRef};
push(@{$temp}, $param) if defined $param;
return $self->{arrayRef};
}

and trying to iterate over a Node's array(which will contain more Nodes that it is connected to):

my $firstnode = Node->new();  # Node constructor should have @array of
my $secondnode = Node->new();

$firstnode->getSetCode("test"); 
print "The current code is ", $firstnode->getSetCode(), "\n";

my $array_r = $firstnode->getSetArray($secondnode);

$array_r = $firstnode->getSetArray($firstnode);

foreach my $obj (@{$array_r}){
    print $obj;
}

This prints out Node=HASH(0x10092bb00)Node=HASH(0x100907bd8). Which leads me to believe that I am dealing with an array containing 2 nodes (this is what I want). But upon attempting to call any methods of this $obj's I am told that I

Can't call method "getSetNode" without a package or object reference.

I had already previously blessed these two objects when calling new on these nodes. So I'm not sure why they aren't recognized as Nodes and I can't call their methods....

EDIT -

foreach my $obj (@{$array_r}){  
    print $obj->getSetCode();
}

where getSetCode() is

sub getSetCode{
    my $self = shift;
    my $param = shift;
    $self->{code} = $param if defined $param;
    return $self->{code};
}

ysth · Accepted Answer · 2011-02-22 05:55:38Z

1

Show how you are trying to call getSetNode on $obj, and the code of getSetNode?

By the way, $temp isn't needed; you can directly do:

push @{ $self->{arrayRef} }, $param if defined $param;

Maybe helpful to you: http://perlmonks.org/?node=References+quick+reference

Also note that you are setting up a cyclical data structure ($firstnode indirectly referencing itself) that perl won't garbage collect automatically, even when all external references go away; you can fix this (if this is even a concern) with:

if (defined $param) {
    push @{ $self->{arrayRef} }, $param;
    Scalar::Util::weaken( $self->{arrayRef}[-1] ) if $param == $self;
}

As far as your problem goes, putting all your code together (and adding a missing , on the coordinates line) into this:

use warnings;
use strict;
package Node;

sub new {
    my $class = shift;
    my @array = ();
    my $array_r = \@array;
    my $self = {
        code => undef,
        name => undef,
        country => undef,
        continent => undef,
        timezone => undef,
        coordinates => undef,
        population => undef,
        region => undef,
        arrayRef => $array_r,
        @_,
    };
    bless $self, $class;
    return $self;
}

sub getSetArray{
    my $self = shift;
    my $param = shift;
    my $temp = $self->{arrayRef};
    push(@{$temp}, $param) if defined $param;
    return $self->{arrayRef};
} 

sub getSetCode{
    my $self = shift;
    my $param = shift;
    $self->{code} = $param if defined $param;
    return $self->{code};
}


my $firstnode = Node->new();  # Node constructor should have @array of
my $secondnode = Node->new();
$secondnode->getSetCode("test2");

$firstnode->getSetCode("test"); 
print "The current code is ", $firstnode->getSetCode(), "\n";

my $array_r = $firstnode->getSetArray($secondnode);

$array_r = $firstnode->getSetArray($firstnode);

foreach my $obj (@{$array_r}){  
    print $obj->getSetCode(), "\n";
}

gives this output for me:

The current code is test
test2
test

edited Feb 22, 2011 at 5:55

answered Feb 22, 2011 at 5:43

ysth

99.1k6 gold badges126 silver badges219 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

arjun nayini Over a year ago

I've added the extra function info

arjun nayini Over a year ago

This is what I want to happen, but not the output being produced on my end. The only difference is that the Node class is defined in another file called Node.pm and that is being 'used' in the main.pl file. I'd rather keep my Node implementation separate from the main.pl file. Is there a reason you know of for why this is happening? (Also the lack of a comma in the Node constructor is not there in my code and must have been lost somehow in my writing up of the question).

arjun nayini Over a year ago

I think the biggest problem I had was that I was initializing the @array in a give node to undef. I changed this to the empty list () and now I'm getting this to work. Thank you for your help. I'm about 5 hours into learning perl and a lot of stuff is still shaky. Definitely a cool language and I'm taking a course in bioinformatics, so I'll probably get to see its powers in action there.

ysth Over a year ago

Ah, yes, @array = undef puts a single undef element into array, and that element wouldn't be able to successfully call a method.

Collectives™ on Stack Overflow

Another simple Perl question...(hash to an array of objects)

1 Answer 1

4 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

4 Comments

Your Answer

Sign up or log in

Post as a guest

Related