Get Values from XML attribute/value combination using XSL

Question

First of all, to the best of my knowledge, this is not about just xml transformation using XSL. It's about the way the xml is being presented to me. I've searched all I can but I can't find a scenario similar to the one I have.

XML source:

<?xml version="1.0"?>
<RepData xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
    <Header>
        <requestId>2313022420.01</requestId>
        <requestTimeStamp>2018-JUN-30T06:13:40Z</requestTimeStamp>
    </Header>
    <responseProcessing>
        <translatorContext/>
        <styleSheet/>
    </responseProcessing>
    <serviceResponse>
        <Report docType="ACCOUNT">
            <dataSet name="ACCOUNT_DETS">
                <fieldDefinition index="1" id="ACCOUNT_ID" label="Account Number" type="ALPHANUMERIC" length="19" repeatable="FALSE"/>
                <fieldDefinition index="2" id="ACCOUNT_NAME" label="Account Name" type="ALPHANUMERIC" length="35" repeatable="FALSE"/>
                <fieldDefinition index="3" id="CURRENCY" label="Currency" type="ALPHANUMERIC" length="25" repeatable="FALSE"/>
                <fieldDefinition index="4" id="AMOUNT" label="Account Balance" type="ALPHANUMERIC" length="19" repeatable="FALSE"/>
                <record>
                    <field index="1">100004087</field>
                    <field index="2">MY EURO ACCOUNT</field>
                    <field index="3">Euro</field>
                    <field index="4">530,000</field>
                </record>
                <record>
                    <field index="1">200008169</field>
                    <field index="2">USD CASH ACCOUNT</field>
                    <field index="3">US Dollar</field>
                    <field index="4">2,924.82</field>
                </record>
            </dataSet>
        </Report>
    </serviceResponse>
</RepData>

From the source, the fields are defined under the fieldDefinition element. And the values are in the field element.

I can't seem to get a way to iterate through fields to pick the field values.

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="RepData/serviceResponse/Report/dataSet/record" >
  <html>
  <body>
    <table border="1">
      <tr bgcolor="#9acd32">
        <th>Account</th>
        <th>Balance</th>
      </tr>
      <xsl:for-each select="RepData/serviceResponse/Report/dataSet/record/field">
<p>
            <xsl:value-of select="RepData/serviceResponse/Report/dataSet/record/field" />
</p>
      </xsl:for-each>
    </table>
  </body>
  </html>
</xsl:template>
</xsl:stylesheet>

The XSL above only returns blank but if I add 'mode="toc"' to the match all data I get a dump of all values in the xml:

2313022420.01 2018-JUN-30T06:13:40Z 100004087 MY EURO ACCOUNT Euro 530,000 200008169 USD CASH ACCOUNT US Dollar 2,924.82

This is what I'm going for (the field names are from the label attribute in fieldDefinition):

Account Number|Account Name       |Currency  |Account Balance
100004087     |MY EURO ACCOUNT    |Euro      |530,000
200008169     |USD CASH ACCOUNT   |US Dollar |2,924.82

Aniket V · Accepted Answer · 2018-06-30 06:37:30Z

The template match and the inner for-each loop are incorrect. You can make the following changes to get the HTML table.

Assuming the number of field elements within record matches with the number of fieldDefinition elements (4 in this case), you can use the below template. There can be multiple options to get the output and here I have used multiple for-each loops. You can also use a template approach to get the output.

<!-- Template match with document root element  -->
<xsl:template match="/">
    <html>
        <body>
            <table border="1">
                <tr bgcolor="#9acd32">
                    <!-- Loop to generate the header row of the table -->
                    <xsl:for-each select="RepData/serviceResponse/Report/dataSet/fieldDefinition">
                        <th><xsl:value-of select="@label" /></th>
                    </xsl:for-each>
                </tr>
                <!-- Loop for each "record" -->
                <xsl:for-each select="RepData/serviceResponse/Report/dataSet/record">
                    <tr>
                        <!-- Loop for each column below the header -->
                        <xsl:for-each select="field">
                            <td><xsl:value-of select="." /></td>
                        </xsl:for-each>
                    </tr>
                </xsl:for-each>
            </table>
        </body>
    </html>
</xsl:template>

Output

imran · Accepted Answer · 2018-06-30 11:26:43Z

<xsl:template match="RepData">
        <xsl:for-each select="serviceResponse/Report/dataSet">
            <table>
                <thead>
                    <tr bgcolor="green">
                        <xsl:for-each select="fieldDefinition">
                        <th>
                            <xsl:value-of select="@label"/>
                        </th>
                        </xsl:for-each>
                    </tr>
                </thead>
                <tbody>
                    <xsl:for-each select="record">
                    <tr bgcolor="blue">
                       <xsl:for-each select="field">
                            <td style="color:white;">
                                <xsl:value-of select="."/>
                            </td>     
                       </xsl:for-each>

                    </tr>
                    </xsl:for-each>
                </tbody>
            </table>
        </xsl:for-each>
    </xsl:template>

Collectives™ on Stack Overflow

Get Values from XML attribute/value combination using XSL

2 Answers 2

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related