How to download and get values from JSON file using VBScript or batch file?

Question

This is the VBScript code answered here to get the JSON file from computer with proper values.

Set fso = CreateObject("Scripting.FileSystemObject")

json = fso.OpenTextFile("C:\path\to\combined.json").ReadAll

Set re = New RegExp
re.Pattern = """passed"":(true|false),"
re.IgnoreCase = True

For Each m In re.Execute(json)
  passed = CBool(m.SubMatches(0))
Next

But I have a JSON file that looks like this which is online,

["AA-BB-CC-MAKE-SAME.json","SS-ED-SIXSIX-TENSE.json","FF-EE-EE-EE-WW.json","ZS-WE-AS-FOUR-MINE.json","DD-RF-LATERS-LATER.json","FG-ER-DC-ED-FG.json"]

How to download this JSON file and get the values to five variables using either VBScript or batch file?

check this - stackoverflow.com/questions/28143160/… and this - stackoverflow.com/questions/47048992/… — npocmaka
– npocmaka, Commented Jul 19, 2018 at 21:46
Consider using PowerShell for this. You life will become a lot easier. — Ansgar Wiechers
– Ansgar Wiechers, Commented Jul 19, 2018 at 21:50

Hackoo · Accepted Answer · 2018-07-20 15:26:26Z

1

Here is an example for downloading a json from internet and parse it :

Dim http,URL
URL = "http://ip-api.com/json/"
Set http = CreateObject("Msxml2.XMLHTTP")
http.open "GET",URL,False
http.send
strJson = http.responseText

Set j = ParseJson(strJson)
Result = "IP =" & j.query & vbCrlf &_
"ISP = "& j.isp & vbCrlf &_
"Country = "& j.country & vbCrlf &_
"TimeZone = "& j.timezone

Wscript.echo Result
'--------------------------------------------------------
Function ParseJson(strJson)
    Set html = CreateObject("htmlfile")
    Set window = html.parentWindow
    window.execScript "var json = " & strJson, "JScript"
    Set ParseJson = window.json
End Function
'--------------------------------------------------------

You can give a try for this code :

Dim http,URL
URL = "https://privateURL/jsonfile/"
Set http = CreateObject("Msxml2.XMLHTTP")
http.open "GET",URL,False
http.send
strJson = http.responseText
Result = Extract(strJson,"(\x22(.*)\x22)")
Arr = Split(Result,",")
For each Item in Arr
    wscript.echo Item
Next
'******************************************
Function Extract(Data,Pattern)
   Dim oRE,oMatches,Match,Line
   set oRE = New RegExp
   oRE.IgnoreCase = True
   oRE.Global = True
   oRE.Pattern = Pattern
   set oMatches = oRE.Execute(Data)
   If not isEmpty(oMatches) then
       For Each Match in oMatches  
           Line = Line & Trim(Match.Value) & vbCrlf
       Next
       Extract = Line
   End if
End Function
'******************************************

edited Jul 20, 2018 at 15:26

answered Jul 20, 2018 at 3:02

Hackoo

18.9k3 gold badges48 silver badges84 bronze badges

Sign up to request clarification or add additional context in comments.

7 Comments

Codename K Over a year ago

I get this error at line 9 char 1, "Object doesn't support this property or method: 'j.query'. Code 800A01B6"

Hackoo Over a year ago

@CodenameK You should provide me the real link of your json file to try to parse it correctly, in my example just works for the link in the script !

Codename K Over a year ago

Did you get the link?

Codename K Over a year ago

It works. Can you change the link in your answer as the link is personal?

Hackoo Over a year ago

@CodenameK Done ;)

|

Collectives™ on Stack Overflow

How to download and get values from JSON file using VBScript or batch file?

1 Answer 1

7 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

7 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related