Generics, iterate over Dynamic Array

Question

I'm trying to iterate over a Dynamic array passed into a generic function

I'm using TValue to achive this, but i can't get the length of the array and there for I can not get the elements.

I've written a small demo project to illustrate my problem:

program Project1;

{$APPTYPE CONSOLE}
{$R *.res}

uses
  System.SysUtils, System.TypInfo, System.Rtti;

type
  TMyEnum = (me_One, me_Two, me_Three);

  Writer = class
  public
    class procedure Write<T>(Value: T);
  end;

  { Writer }

class procedure Writer.Write<T>(Value: T);
var
  ArrayValue: TValue;
  TypeInfo: pTypeInfo;
begin
  TypeInfo := System.TypeInfo(T);

  if TypeInfo.Kind <> tkDynArray then
    exit;

  TValue.Make(nil, TypeInfo, ArrayValue);
  Writeln(ArrayValue.GetArrayLength);
//Here I have my problem ArrayValue.GetArrayLength returns 0 and not 2 
end;

var
  Enums: array of TMyEnum;
  Dummy : String;
begin
  try
    SetLength(Enums, 2);
    Enums[0] := me_One;
    Enums[1] := me_Two;

    Writer.Write(Enums);
    Readln(Dummy);
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;

end.

It works for a static Array, thats why I used the same approach for dynamic arrays — Jens Borrisholt
– Jens Borrisholt, Commented Sep 27, 2018 at 8:11

Jens Borrisholt · Accepted Answer · 2018-09-27 08:29:12Z

4

I found the answer my self. The problem where I was using TValue.Make and not TValue.From

This will do. Way more simple compared to where I started.

class function Writer.WriteLine<T>(AValue: T): string;
var
  ElementValue, Value: TValue;
  i: Integer;
begin
  Value := TValue.From(AValue);
  try
    if not Value.IsArray then
      Exit('');

    if Value.GetArrayLength = 0 then
      Exit('[]');

    Result := '[';

    for i := 0 to Value.GetArrayLength - 1 do
    begin
      ElementValue := Value.GetArrayElement(i);
      Result := Result + ElementValue.ToString + ',';
    end;

    Result[Length(Result)] := ']';
  finally
    Writeln(Result);
  end;
end;

answered Sep 27, 2018 at 8:29

Jens Borrisholt

6,4242 gold badges38 silver badges72 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

gabr Over a year ago

In Tokyo, there is not TValue.From, just TValue.From<T>, which translates to Make(@Value, ... and that's exactly what Sebastian Proske suggested.

Collectives™ on Stack Overflow

Generics, iterate over Dynamic Array

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related