Extract hyperlink using CSS selector query

Question

I would like to extract the hyperlink from a webpage by using queryselector all, but there are no results coming out.

Below is my code.

Sub ScrapLink()

Application.ScreenUpdating = False
Dim IE As New InternetExplorer, html As HTMLDocument
Dim x As Long    
Application.ScreenUpdating = False
With IE
IE.Visible = True
IE.Navigate "http://www.bursamalaysia.com/market/listed-companies/company-announcements/5978065" 
While .Busy Or .ReadyState < 4: DoEvents: Wend
Application.Wait Now + TimeSerial(0, 0, 1)
DoEvents

With .Document.getElementById("bm_ann_detail_iframe").contentDocument
     Dim links As Object, i As Long
     Set links = .Document.querySelectorAll("p.att_download_pdf[href^='/FileAccess/apbursaweb/']")
     For i = 1 To links.Length
      With ThisWorkbook.Worksheets("Sheet1")
       Range("A" & Rows.Count).End(xlUp).Offset(1).Value = links.Item(i - 1)
    End With
   Next i
  .Quit
  End With
 End With
End Sub

change Set links = .Document.querySelectorAll("p.att_download_pdf[href^='/FileAccess/apbursaweb/']") to Set links = .querySelectorAll("a[href^='/FileAccess/apbursaweb/']") — Pᴇʜ
– Pᴇʜ, Commented Nov 19, 2018 at 12:56

QHarr · Accepted Answer · 2018-11-19 14:07:30Z

2

You could just avoid the initial page and use the URL direct from the frame. This would be my preference unless you don't know, for some reason, this URL.

Option Explicit

Public Sub GetInfo()
    Dim IE As New InternetExplorer, nodeList As Object, i As Long
    With IE
        .Visible = True
        .navigate2 "http://disclosure.bursamalaysia.com/FileAccess/viewHtml?e=2906127"

        While .Busy Or .readyState < 4: DoEvents: Wend

        Set nodeList = .document.querySelectorAll(".att_download_pdf [href^='/FileAccess/apbursaweb/download']")
        For i = 0 To nodeList.Length - 1
            Debug.Print nodeList.item(i).href
        Next
        .Quit
    End With
End Sub

Or you can jump right on over to the iframe src after page load:

Option Explicit   
Public Sub GetInfo()
    Dim IE As New InternetExplorer, nodeList As Object, i As Long
    With IE
        .Visible = True
        .Navigate2 "http://www.bursamalaysia.com/market/listed-companies/company-announcements/5978065"

        While .Busy Or .readyState < 4: DoEvents: Wend      
        .Navigate2 .document.querySelector("iframe").src           
        While .Busy Or .readyState < 4: DoEvents: Wend

        Set nodeList = .document.querySelectorAll(".att_download_pdf [href^='/FileAccess/apbursaweb/download']")
        For i = 0 To nodeList.Length - 1
            Debug.Print nodeList.item(i).href
        Next
        .Quit
    End With
End Sub

edited Nov 19, 2018 at 14:07

answered Nov 19, 2018 at 13:54

QHarr

84.5k14 gold badges58 silver badges105 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Hong Yew Over a year ago

Thank for your advice. :)

SIM · Accepted Answer · 2018-11-19 13:20:25Z

1

Try the following. It should fetch you the links you wish to grab:

Sub ScrapLink()
    Dim IE As New InternetExplorer, Html As HTMLDocument
    Dim frame As Object, i As Long

    With IE
        .Visible = True
        .navigate "http://www.bursamalaysia.com/market/listed-companies/company-announcements/5978065"
        While .Busy Or .readyState < 4: DoEvents: Wend
        Set Html = .document
    End With

    Application.Wait Now + TimeValue("00:00:03") 'This delay may vary in your case

    Set frame = Html.getElementById("bm_ann_detail_iframe").contentWindow.document
    With frame.querySelectorAll("p.att_download_pdf a")
        For i = 0 To .Length - 1
            Cells(i + 1, 1) = .item(i).getAttribute("href")
        Next i
    End With
End Sub

If you wish to kick out the delay then try changing the portion below with the above one:

Do: Set frame = Html.getElementById("bm_ann_detail_iframe"): DoEvents: Loop While frame Is Nothing

With frame.contentWindow.document.querySelectorAll("p.att_download_pdf a")
    For i = 0 To .Length - 1
        Cells(i + 1, 1) = .item(i).getAttribute("href")
    Next i
End With

edited Nov 19, 2018 at 13:20

answered Nov 19, 2018 at 13:07

SIM

22.5k6 gold badges45 silver badges116 bronze badges

1 Comment

Hong Yew Over a year ago

Thank for your solution.

Collectives™ on Stack Overflow

Extract hyperlink using CSS selector query

2 Answers 2

1 Comment

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related