Read output of file or command inline in vim

Question

Lets say I have a text file open in Vim, that looks like so

this is an inline insertion

and I want to add the word "test" between "inline" and "insertion".

I could just write it in, but this is a metaphoric example, so I'm going to :read !printf "test " with the cursor at column 18. Here's what I get:

this is an inline insertion
test

Here's what I want to get:

this is an inline test insertion

Is there any way to create a vim function or is there an existing command I can use to get this behavior? I know I could do the read, then do D k, then place the cursor, then P, but I was hoping to find a way to do this in one step, placing the cursor ahead of time.

EDIT

Thanks to @melpomene's answer, I have this function in my ~/.vimrc file now:

fu! InlineRead(command)
  let colnum = col('.')
  let line = getline('.')
  call setline('.', strpart(line, 0, colnum) . system(a:command) . strpart(line, colnum))
endfu

melpomene · Accepted Answer · 2018-12-27 19:07:02Z

3

You can do it manually by combining a few other functions:

:call setline('.', strpart(getline('.'), 0, col('.')) . system('printf "test "') . strpart(getline('.'), col('.')))

Of course you can simplify this a bit by assigning the results of e.g. col('.') and getline('.') to variables, removing redundant computation:

let c = col('.')
let line = getline('.')
call setline('.', strpart(line, 0, c) . system('printf "test "') . strpart(line, c))

answered Dec 27, 2018 at 19:07

melpomene

86.2k8 gold badges96 silver badges154 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Ingo Karkat · Accepted Answer · 2019-01-18 14:06:28Z

Without any setup (as in @melpomene's answer), you can directly insert external command output via :help c_CTRL-R, the expression register (:help quote=), and :help system() in insert mode:

<C-R>=system('printf "test "')<CR>

An alternative implementation is the following <C-R>` mapping for insert and command-line mode:

custom mapping

" i_CTRL-R_`        Insert the output of an external command.
" c_CTRL-R_`
function! s:QueryExternalCommand( newlineReplacement )
    call inputsave()
    let l:command = input('$ ', '', 'shellcmd')
    call inputrestore()
    return (empty(l:command) ?
    \   '' :
    \   substitute(substitute(l:command, '\n\+$', '', ''), '\n', a:newlineReplacement, 'g')
    \)
endfunction
inoremap <C-r>` <C-g>u<C-r>=<SID>QueryExternalCommand('\r')<CR>
cnoremap <C-r>` <C-r>=<SID>QueryExternalCommand('\\n')<CR>

Collectives™ on Stack Overflow

Read output of file or command inline in vim

EDIT

2 Answers 2

Comments

custom mapping

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

EDIT

2 Answers 2

Comments

custom mapping

Comments

Your Answer

Sign up or log in

Post as a guest

Related