This is basically what I want in a batch file. I want to be able to re-run "Do Stuff" whenever I press any key to go past the "Pause".
while(true){
Do Stuff
Pause
}
Looks like there are only for loops available and no while loops in batch. How do I create an infinite loop then?
How about using good(?) old goto?
:loop
echo Ooops
goto loop
See also this for a more useful example.
:lbl & echo Ooops & goto lbl ; but @Nicholi 's comment below does: FOR /L (1,0,2) DO @echo Oops
Unlimited loop in one-line command for use in cmd windows:
FOR /L %N IN () DO @echo Oops
A really infinite loop, counting from 1 to 10 with increment of 0.
You need infinite or more increments to reach the 10.
You can also use the short form: for ... in () do
for /L %%n in (1,0,10) do (
echo do stuff
rem ** can't be leaved with a goto (hangs)
rem ** can't be stopped with exit /b (hangs)
rem ** can be stopped with exit
rem ** can be stopped with a syntax error
call :stop
)
:stop
call :__stop 2>nul
:__stop
() creates a syntax error, quits the batch
This could be useful if you need a really infinite loop, as it is much faster than a goto :loop version because a for-loop is cached completely once at startup.
** pseudo infinite **
If you need a loop that is fast (then you shouldn't use GOTO), but the loop should be breakable, it's possible to use nested loops.
@echo off
setlocal EnableDelayedExpansion
set cnt=0
REM *** 6 nested loops, each count from 0 to 255
for /L %%L in (0 1 255) do for /L %%L in (0 1 255) do for /L %%L in (0 1 255) do for /L %%L in (0 1 255) do for /L %%L in (0 1 255) do for /L %%L in (0 1 255) do (
set /a cnt+=1
echo Loop !cnt!
if !cnt! == 10 goto :break
)
:break
It loops 2⁴⁸ (=281474976710656) times, but if the goto breaks the loops, it needs a maximum of 1536 empty loops.
read help GOTO
and try
:again
do it
goto again
Another better way of doing it:
:LOOP
timeout /T 1 /NOBREAK
::pause or sleep x seconds also valid
call myLabel
if not ErrorLevel 1 goto :LOOP
This way you can take care of errors too
Here is an example of using the loop:
echo off
cls
:begin
set /P M=Input text to encode md5, press ENTER to exit:
if %M%==%M1% goto end
echo.|set /p ="%M%" | openssl md5
set M1=%M%
Goto begin
This is the simple batch i use when i need to encrypt any message into md5 hash on Windows(openssl required), and the program would loyally repeat itself except given Ctrl+C or empty input.
For CommandOr Link