Perl - function with two array arguments

Question

I have troubles using a function in Perl.

My function has 2 arguments which are arrays :

sub get_coordinate {
    my (@array_col, @array_lin) = (@_);

    do some stuff
}

I call it this way :

    $index_col                  = int(rand(10));
    $index_lin                  = int(rand(10));
    @array_col                  = (0,0,0,0,0,0,0,0,0,0);
    @array_lin                  = (0,0,0,0,0,0,0,0,0,0);
    $array_col[$index_col]      = 1;
    $array_lin[$index_lin]      = 1;

    get_coordinate(@array_col, @array_lin);

My problem is that I get the error message : Use of uninitialized value within @array_lin in numeric eq (==) at switch.pl line 82 (#1) (W uninitialized) An undefined value was used as if it were already defined. It was interpreted as a "" or a 0, but maybe it was a mistake. To suppress this warning assign a defined value to your variables.

I don't understand why @array_col is initialized an not @array_lin.

When I print @array_col and @array_lin inside the function this way :

print "@array_col\n@array_lin\n";

I get : 0 0 0 0 0 0 0 1 0 0 1 0 0 0 0 0 0 0 0 0

Any idea ?

Thx, SLP

It is not possible to pass two array arguments by value, all parameter will end up in the first array. Pass them by reference instead. For example, get_coordinate(\@array_col, \@array_lin) — Håkon Hægland
– Håkon Hægland, Commented Feb 27, 2019 at 10:39
@SLP Re: "What do you mean by pass by reference": See perlref — Håkon Hægland
– Håkon Hægland, Commented Feb 27, 2019 at 10:41

ysth · Accepted Answer · 2019-02-27 15:01:13Z

8

In Perl, all lists are flat. These two lists are equivalent.

( 1, 2, ( 3, 4, ( 5 ), (6, 7), 8), (), )
( 1, 2, 3, 4, 5, 6, 7, 8 )

The same thing also happens when take several arrays and stick them in a list.

my @foo = (1, 2, 3);
my @bar = (4, 5, 6);
my @new = (@foo, @bar); # 1, 2, 3, 4, 5, 6

When you pass things to a function, those things get turned into a list of arguments. Therefore, the arrays will both end up in one list, like @foo and @bar above.

frobnicate(@foo, @bar);

When you assign something in list context, the entire list will be assigned left to right. For scalars in the list on the left-hand-side this means they will get their values. But as soon as there is an array, this will be greedy. It will suck up all the remaining values.

my ($one, $two, @rest, $will_be_undef) = (1, 2, 3, 4, 5, 6);

The values will be assigned like this:

$one = 1;
$two = 2;
@rest = ( 3, 4, 5, 6 );
$will_be_undef = undef;

What you need to do to pass two arrays is to take references, and dereference them in our function.

frobnicate( \@foo, \@bar );

sub frobnicate {
    my ($first_array, $second_array) = @_;

    my @foo = @{ $first_array };
    my @bar = @{ $second_array };

    ...
}

edited Feb 27, 2019 at 15:01

ysth

99.1k6 gold badges126 silver badges219 bronze badges

answered Feb 27, 2019 at 10:48

simbabque

54.4k8 gold badges77 silver badges141 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

SLP Over a year ago

Thank you for the well detailed answer

choroba · Accepted Answer · 2019-02-27 10:43:03Z

2

Assigning to several arrays (or hashes) doesn't do what you think:

my (@array1, @array2) = ...

The first array gets all the elements. How should it know where to stop?

You can use array references instead:

sub get_coordinate {
    my ($arr1, $arr2) = @_;
    my @arr1 = @$arr1;
    my @arr2 = @$arr2;
    ...
}
get_coordinate(\@array1, \@array2);

answered Feb 27, 2019 at 10:43

choroba

245k27 gold badges221 silver badges304 bronze badges

Collectives™ on Stack Overflow

Perl - function with two array arguments

2 Answers 2

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related