SoftwareSerial Error ESP8266-01 With Arduino UNO

Question

I have a problem with my Arduino code, I want to communicate between ESP8266-01 and Arduino UNO R3 using the softwareserial library.

This is the code that I use

ESP8266-01 as Transmitter

#include <ESP8266WiFi.h>

// Replace with your network credentials
const char* ssid     = "farzain_2";
const char* password = "1999fzyc";

// Set web server port number to 80
WiFiServer server(80);

// Variable to store the HTTP request
String header;

// Auxiliar variables to store the current output state
String output5State = "off";
String output4State = "off";

// Assign output variables to GPIO pins

void setup() {
  Serial.begin(9600);

  // Connect to Wi-Fi network with SSID and password
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  // Print local IP address and start web server
  Serial.println("");
  Serial.println("WiFi connected.");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  server.begin();
}

void loop(){
  WiFiClient client = server.available();   // Listen for incoming clients

  if (client) {                             // If a new client connects,
    Serial.println("New Client.");          // print a message out in the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    while (client.connected()) {            // loop while the client's connected
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        //Serial.write(c);                    // print it out the serial monitor
        header += c;
        if (c == '\n') {                    // if the byte is a newline character
          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println("Connection: close");
            client.println();

            // turns the GPIOs on and off
            if (header.indexOf("GET /5/on") >= 0) {
              Serial.println("GPIO 5 on");
              output5State = "on";
              Serial.write("LED 1 ON");
            } else if (header.indexOf("GET /5/off") >= 0) {
              Serial.println("GPIO 5 off");
              output5State = "off";
              Serial.write("LED 2 OFF");
            } else if (header.indexOf("GET /4/on") >= 0) {
              Serial.println("GPIO 4 on");
              output4State = "on";
              Serial.write("LED 2 ON");
            } else if (header.indexOf("GET /4/off") >= 0) {
              Serial.println("GPIO 4 off");
              output4State = "off";
              Serial.write("LED 2 OFF");
            }

            // Display the HTML web page
            client.println("<!DOCTYPE html><html>");
            client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
            client.println("<link rel=\"icon\" href=\"data:,\">");
            // CSS to style the on/off buttons 
            // Feel free to change the background-color and font-size attributes to fit your preferences
            client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
            client.println(".button { background-color: #195B6A; border: none; color: white; padding: 16px 40px;");
            client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
            client.println(".button2 {background-color: #77878A;}</style></head>");

            // Web Page Heading
            client.println("<body><h1>ESP8266 Web Server</h1>");

            // Display current state, and ON/OFF buttons for GPIO 5  
            client.println("<p>GPIO 5 - State " + output5State + "</p>");
            // If the output5State is off, it displays the ON button       
            if (output5State=="off") {
              client.println("<p><a href=\"/5/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/5/off\"><button class=\"button button2\">OFF</button></a></p>");
            } 

            // Display current state, and ON/OFF buttons for GPIO 4  
            client.println("<p>GPIO 4 - State " + output4State + "</p>");
            // If the output4State is off, it displays the ON button       
            if (output4State=="off") {
              client.println("<p><a href=\"/4/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/4/off\"><button class=\"button button2\">OFF</button></a></p>");
            }
            client.println("</body></html>");

            // The HTTP response ends with another blank line
            client.println();
            // Break out of the while loop
            break;
          } else { // if you got a newline, then clear currentLine
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }
      }
    }
    // Clear the header variable
    header = "";
    // Close the connection
    client.stop();
    Serial.println("Client disconnected.");
    Serial.println("");
  }
}

Arduino UNO as Receiver

#include <SoftwareSerial.h>

SoftwareSerial mySerial(2,3); //RX, TX

const int LED_ONE = 6;
const int LED_TWO = 7;

void setup(){
    Serial.begin(9600);
    mySerial.begin(9600);
    pinMode(LED_ONE, OUTPUT);
    pinMode(LED_TWO, OUTPUT);
}

void loop(){
  String IncomingString = "";
  boolean StringReady = false;

  while(mySerial.available()){
    IncomingString = mySerial.readString();
    StringReady = true;
  }
  if(StringReady) {
    Serial.print("From ESP = ");
    Serial.println(IncomingString);

    if(IncomingString = "LED 1 ON") {
      Serial.println("");
      Serial.println("LED 1 ON");
      Serial.println("");
      digitalWrite(LED_ONE, HIGH);
    }
    if(IncomingString = "LED 1 OFF") {
      Serial.println("");
      Serial.println("LED 1 OFF");
      Serial.println("");
      digitalWrite(LED_ONE, LOW);
    }
    if(IncomingString = "LED 2 ON") {
      Serial.println("");
      Serial.println("LED 2 ON");
      Serial.println("");
      digitalWrite(LED_TWO, HIGH);
    }
    if(IncomingString = "LED 2 OFF") {
      Serial.println("LED 2 OFF");
      Serial.println("");
      digitalWrite(LED_TWO, LOW);
    }
  }
}

what I know about this softwareserial library is that the receiver will only receive a message from the transmitter using Serial.write in code ESP8267-01 (Transmitter) But it turns out that there are many messages that go to Arduino Uno which are not using serial.write, this is the result of the serial monitor

From ESP = New Client.

LED 1 ON

LED 1 OFF

LED 2 ON

LED 2 OFF

From ESP = Client disconnected.

LED 1 ON

LED 1 OFF

LED 2 ON

LED 2 OFF

is there something wrong with my code above? thank you

datafiddler · Accepted Answer · 2019-03-29 23:29:28Z

0

if(IncomingString = "LED 1 ON")

... assigns the text to the variable and returns true, as it is not NULL

You probably want to compare a String with a Literal. Use == instead :)

answered Mar 29, 2019 at 23:29

datafiddler

1,8353 gold badges20 silver badges32 bronze badges

Sign up to request clarification or add additional context in comments.

Collectives™ on Stack Overflow

SoftwareSerial Error ESP8266-01 With Arduino UNO

1 Answer 1

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

Comments

Your Answer

Sign up or log in

Post as a guest

Related