What the equivalent of BYTE array (BYTE[]) in Delphi with null termination a integer?

Question

I'm stuck in this trouble where the compiler says:

Incompatible types: 'AnsiChar' and 'Integer'

to the last element of AnsiChar array, that is a integer that is a null termination. How fix it?

C++ code:

static const BYTE  myarray[] = { 'A', 'B', 'C', 'D', 'E', 'F', 'G', 'H', 'I', 0 };
SOCKET s;

// Usage example:
if(Send(s, (char *) myarray, sizeof(myarray), 0) <= 0)
      return;

My attempt in Delphi:

var
  MyArray: array [0 .. MAX_PATH] of AnsiChar = ( 'A', 'B', 'C', 'D', 'E', 'F', 'G', 'H', 'I', 0 );
  S: TSocket;

// Usage example:
send(S, MyArray, Length(MyArray), 0);

@Rudy It's not the best dupe. I reopened it. Please post your answer. Best explain ordinal char literals too. Thanks. — David Heffernan
– David Heffernan, Commented Apr 15, 2019 at 14:04

Rudy Velthuis · Accepted Answer · 2019-04-15 19:47:02Z

7

You can almost define it the way you did:

var
  MyArray: array[0..MAX_PATH] of AnsiChar = ('A', 'B', 'C', 'D', 'E', 'F', 'G', 'H', 'I', #0);

But then you get an error complaining about the number of elements, so you would have to add some 250 extra zeroes to complete it:

// Possible, but not necessary, see below 
var
  MyArray: array[0..MAX_PATH] of AnsiChar = 
    ('A', 'B', 'C', 'D', 'E', 'F', 'G', 'H', 
     'I',  #0,  #0,  #0,  #0, ....
                ...
                ...
                ...            #0,  #0,  #0);

This can be done much simpler, however:

var
  MyArray: array[0..MAX_PATH] of AnsiChar = 'ABCDEFGHI';

This special syntax should work in most versions of Delphi and not get a compiler error.

For the length during a send(), you'll have to use StrLen(), not Length():

send(S, MyArray, StrLen(MyArray) + 1, 0);

Alternatively, you can do this:

var
  Stg: AnsiString;
begin
  Stg := 'ABCDEFGHI';
  // Second parameter is untyped const, so use ^
  send(S, PAnsiChar(Stg)^, Length(Stg) + 1, 0);

FWIW, #0 is the character with ordinal value 0. Alternatives are:

Chr(0)
#0
^@ (meaning Control+@; ^A = #1 = Chr(1), ^M = #13, etc.)

Each of the above has the same meaning.

edited Apr 15, 2019 at 19:47

answered Apr 15, 2019 at 14:14

Rudy Velthuis

28.9k5 gold badges50 silver badges97 bronze badges

Sign up to request clarification or add additional context in comments.

9 Comments

David Heffernan Over a year ago

Isn't Length the length of the array? And so not equal to the sizeof from the C++ code.

Rudy Velthuis Over a year ago

@David: Length(MyArray) is MAX_PATH+1. Just checked that. Updated my answer.

FLASHCODER Over a year ago

@RudyVelthuis, E2036 Variable required here: PAnsiChar(Stg) on alternative solution of your answer. How fix?

Rudy Velthuis Over a year ago

I did not know that the second parameter of send is a var parameter (probably an untyped var parameter?). In that case, you'll have to pass PAnsiChar(Stg)^ (note the added ^).

Remy Lebeau Over a year ago

Why is MAX_PATH being used at all? In the original C++ code, the array length is only 10 chars max, not the 261 chars that the Delphi code is forcing. Fix the array as MyArray: array [0 .. 9] of AnsiChar, then Sizeof() can be used in the Delphi code instead of using Length() or StrLen()+1

|

Remy Lebeau · Accepted Answer · 2019-04-15 23:30:45Z

3

You can use #0 to represent numeric 0 as an AnsiChar. But, the C++ code is assigning char values to a BYTE array, and you can't implicitly assign an AnsiChar to a Byte in Delphi, you need a type-cast.

A literal translation of the C++ code to Delphi would look more like this:

const
  myarray[0..9] of Byte = (Ord('A'), Ord('B'), Ord('C'), Ord('D'), Ord('E'), Ord('F'), Ord('G'), Ord('H'), Ord('I'), 0);
  // alternatively:
  // myarray[0..9] of AnsiChar = ('A', 'B', 'C', 'D', 'E', 'F', 'G', 'H', 'I', #0);

var
  s: SOCKET;
begin
  ...
  // Usage example:
  if (send(s, myarray, SizeOf(myarray), 0) <= 0) then
    Exit;
  ...
end;

answered Apr 15, 2019 at 23:30

Remy Lebeau

609k36 gold badges516 silver badges875 bronze badges

2 Comments

FLASHCODER Over a year ago

based on my last question about send() a PByte type, here we also can make: send(s, myarray^, SizeOf(myarray), 0)? PS: myarray^ or simply myarray? See this.

Remy Lebeau Over a year ago

@BrowJr you can't use ^ to dereference a fixed array in Delphi, only a pointer, and there is no need to use a pointer in this example, in fact there is no need to dereference the fixed array at all

Collectives™ on Stack Overflow

What the equivalent of BYTE array (BYTE[]) in Delphi with null termination a integer?

2 Answers 2

9 Comments

2 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

9 Comments

2 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related