Converting comma separated values into a list using shell

Question

I have a file which looks like this:

Size: 20,30,40
Frequency: 60,70,80

I tried using sed where I replace the , with a new line and text but then that doesn't give me my desired output

sed 's/,/\nSize:/g' infile > outfile

I expect the output to be in a list format like the following manner (each in a new line ):

Size1 :20 
Frequency1: 60 
Size2 :30
Frequency2:70 
Size3 :40
Frequency3:80
 Size4 :
Frequency4: 
Size5 :
Frequency5:

I need two extra columns as some files can have 5 sizes

Please read the description of tags you apply, you choice clearly shows you didn't. Also, as a new user here, take the tour and read How to Ask, in case you haven't already. — Ulrich Eckhardt
– Ulrich Eckhardt, Commented Aug 21, 2019 at 6:45

Shawn · Accepted Answer · 2019-08-20 17:50:18Z

1

$ awk -F: '{ n = split($2, nums, /,/); for (i = 1; i <= n; i++) v[$1,i] = nums[i] }
           END { for (i = 1; i <= 5; i++) {
                   printf("Size%d:%s\n", i, v["Size",i])
                   printf("Frequency%d:%s\n", i, v["Frequency",i])
                 }
           }' input.txt
Size1: 20
Frequency1: 60
Size2:30
Frequency2:70
Size3:40
Frequency3:80
Size4:
Frequency4:
Size5:
Frequency5:

edited Aug 20, 2019 at 17:50

answered Aug 20, 2019 at 17:30

Shawn

53.9k3 gold badges29 silver badges74 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Jotne Over a year ago

There is a spacing problem with all expect the two first, change to -F": " and add a space after Size/Freq.. like this "Size%d: %s\n" to fix it. An idea for OP is to use n instead of 5 on your solution. It will then only print the number of field needed.

Shawn Over a year ago

@Jotne I almost put a space before the colon on the Size lines to better match OP's desired output (and maybe indent Size4...). And he specifically said he wanted the extras for a total of 5...

Jotne · Accepted Answer · 2019-08-21 06:33:10Z

0

A more generic solution based how Shawn's post. It stores line name in array s, so it will work with any number of line with data and any number of fields.

awk -F": " '{
    n=split($2,a,",");
    s[$1]++;
    for(i=1;i<=n;i++)
        v[$1,i]=a[i]} 
END {
    for(i=1;i<=n;i++) {
        for (j in s) 
            printf("%s%d: %s\n",j,i,v[j,i])
        }
    }' file

Frequency1: 60
Size1: 20
Frequency2: 70
Size2: 30
Frequency3: 80
Size3: 40

answered Aug 21, 2019 at 6:33

Jotne

41.7k13 gold badges54 silver badges58 bronze badges

Collectives™ on Stack Overflow

Converting comma separated values into a list using shell

2 Answers 2

2 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related