I am writing a little program and need to split a string with specific values inside.
I have tried multiple different ways but come up empty handed.
[IDNUM]123456[SNUM]00001[DATEC]01012020[END]
using CMD how would i return just the characters between [IDNUM] and [SNUM] to show "123456" ?
Thank you
I'll assume your string is in a variable - I'll call it string, and you want to put the value in variable val.
If the first and second [tags] are always as you have in your example, and no possibility of other [ or ] before [SNUM], then
for /f "delims=[] tokens=3" %%A in ("X%string%") do set "val=%A"
The leading X is added to ensure the correct value is extracted regardless whether the string includes any characters before [idnum].
If the above can't be used because the string does not have a fixed format, then the following can be used provided that
set "val=%string:*[idnum]=%"
set "val=%val:[snum]="&rem %
The first set becomes set "val=123456[SNUM]00001[DATEC]01012020[END]"
The second set becomes set "val=123456"&rem 00001[DATEC]01012020[END]
It should be obvious how that gives the correct value.
Lastly, here is a robust solution that should always work as long as you don't run into maximum string length issues, and the [tags] are not case sensitive.
setlocal disableDelayedExpansion
setlocal enableDelayedExpansion
:: escape \ and | characters
set "val=!string:\=\S!"
set "val=!val:|=\P!"
:: convert [idnum] and [snum] to |
set "val=!val:[idnum]=|!"
set "val=!val:[snum]=|!"
:: parse out the value. delayed expansion is toggled off so it does not corrupt any `!` that might appear within the value
for /f "tokens=2 delims=|" %%A in ("X!val!") do (
endlocal
set "val=%%A"
)
:: restore any \ and |
setlocal enableDelayedExpansion
set "val=!val:\P=|!"
set "val=!val:\S=\!"
If you know that the string can never contain | (or some other character), then it is much simpler:
setlocal disableDelayedExpansion
setlocal enableDelayedExpansion
set "val=!string:[idnum]=|!"
set "val=!string:[snum]=|!"
for /f "tokens=2 delims=|" %%A in ("X!val!") do (
endlocal
set "val=%%A"
)
set "string=[IDNUM]123456[SNUM]00001[DATEC]01012020[END]" set "val=%string:*[idnum]=%" set "val=%val:[snum]="%, perfect
" for [snum] if and only if there are no quotes after [snum]. Everything after the last " is ignored. My original answer was missing a space after the rem, I fixed that error in an edit.A shorter/simpler (2 lines) approach:
@echo off
setlocal
set "string=[IDNUM]123456[SNUM]00001[DATEC]01012020[END]"
rem Replace ']' by '=' giving [IDNUM=123456[SNUM=00001[DATEC=01012020[END=
set "string=%string:]==%"
rem Replace '[' by '" & set "' giving " & set "IDNUM=123456" & set "SNUM=00001" & set "DATEC=01012020" & set "END=
rem and *execute* such a line inserting a 'set "X=' correction before the first '" &'
rem and a quote after the last '='
set "X=%string:[=" & set "%"
rem After this line each one of the variables have their corresponding values
echo IDNUM=%IDNUM%
X value. You might want to change X to some variable name that should never be defined, like CD or ERRORLEVEL, although that would look mighty strange. Or you could use 2>nul set "=%string:[=" & set "%"
set "string=%string:[=" & set "%"Solution for a batch file
@echo off
set "str=[IDNUM]123456[SNUM]00001[DATEC]01012020[END]"
FOR /F "tokens=2 delims=[]" %%A IN ("%str%") DO @ECHO %%A
pause
when changing tokens to 2 you will get 123456, 4 you will get 00001 ....
One more way to do it with a regex.
SET "S=[IDNUM]123456[SNUM]00001[DATEC]01012020[END]"
FOR /F "delims=" %%A IN ('powershell -NoLogo -NoProfile -Command ^
"$null = '%S%' -match '.*\[IDNUM\](.*?)\[.*'; $Matches[1]"') DO (SET "RESULT=%%A")
ECHO RESULT is %RESULT%
FOR /F "tokens=3 delims=[]" %A IN ("str=[IDNUM]123456[SNUM]00001[DATEC]01012020[END]") DO @ECHO %A. In a batch file, use%%Ainstead of%A.set "str=[IDNUM]123456[SNUM]00001[DATEC]01012020[END]"FOR /F "tokens=2 delims=[]" %%A IN ("%str%") DO @ECHO %%A