Access multidimensional Array via String in groovy

Question

I want to access a JSON HasMap via String like data['dimension1']['dimension2'] but i want to do that dynamically like data[myAccessor].

Code

import groovy.json.JsonSlurperClassic

dataContent = '''
{
  "Test": {
    "Info": "Hello"
  }
}
'''

def jsonSlurper = new JsonSlurperClassic()
data = jsonSlurper.parseText(dataContent)

println data['Test']['Info']  // Prints 'Hello'

accessor = "'Test']['Info'"
println data[accessor]  // Prints 'null'

'''

tim_yates · Accepted Answer · 2020-05-13 14:19:42Z

1

Yeah, you can't just execute complex text as code like that 😕 (or 😄, I can't decide)

The best you can do is to have accessor be something splittable like

accessor = 'Test->Info'

And then you can split this and "walk" down the input structure to get the result you're after like so:

import groovy.json.JsonSlurperClassic

dataContent = '''
{
  "Test": {
    "Info": "Hello"
  }
}
'''

def jsonSlurper = new JsonSlurperClassic()
data = jsonSlurper.parseText(dataContent)

accessor = "Test->Info"

println accessor.split('->').inject(data) { currentData, accessorPart ->
    currentData?.getAt(accessorPart)
}

answered May 13, 2020 at 14:19

tim_yates

172k29 gold badges359 silver badges354 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

Dirk Schiller Over a year ago

Thank you a lot Tim !

Dirk Schiller Over a year ago

Can I also use this Technique to change the Hello Value to some other Value ?

cfrick Over a year ago

@DirkSchiller Yes. You can reduce along the path except the last element (e.g. using .dropRight(1)) and then put your value with the last element on the resulting map (if there is one)

jalopaba · Accepted Answer · 2020-05-13 14:46:07Z

1

You can leverage Groovy's Eval and represent the accessor with property notation to have something closer to your intent:

import groovy.json.JsonSlurperClassic

dataContent = '''
{
  "Test": {
    "Info": "Hello"
  }
}
'''

def jsonSlurper = new JsonSlurperClassic()
data = jsonSlurper.parseText(dataContent)

println data.'Test'.'Info' // prints 'Hello'
accessor = "'Test'.'Info'"

Eval.x(data, "println x.${accessor}") // prints 'Hello'

answered May 13, 2020 at 14:46

jalopaba

8,1492 gold badges46 silver badges58 bronze badges

2 Comments

Dirk Schiller Over a year ago

Thank you Jalopaba!

tim_yates Over a year ago

One note on eval is to be wary of user input. Someone sending in "X; System.exit(1)" could halt the jvm

Collectives™ on Stack Overflow

Access multidimensional Array via String in groovy

Code

2 Answers 2

3 Comments

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

Code

2 Answers 2

3 Comments

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related