Perl Regex: Need help on a way to split string into groups matching a pattern

Question

I need to split this string to an array:

$string = "9583526578','9583636523','9673522574','9183556528','9983023378";

Here's how I want my array to look like after splitting:

@foo = [
           [9583526578, 9583636523],
           [9673522574, 9183556528],
           [9983023378]
       ]

As you might have noticed, I need to split this string into groups of n (2 in this example) but still consider remainder if it doesn't match with n.

How can this be done in Perl?

I've done my research and experimentations but can't seem to get it right after a couple of hours.

Thanks for your time! :)

Did you mean to add single quotes before the first number and after the last? — tofutim
– tofutim, Commented Jun 2, 2011 at 2:28
Thanks for everyone's ideas. It helped me explore other possibilities of solving this. :) — cr8ivecodesmith
– cr8ivecodesmith, Commented Jun 2, 2011 at 9:07

Schwern · Accepted Answer · 2011-06-02 06:36:12Z

4

If you can trust they're all integers, extraction is easy. Just grab all the integers.

my @numbers = $string =~ /(\d+)/g;

Then splitting them into pieces of two...

push @matrix, [splice @numbers, 0, 2] while @numbers;

Not as memory efficient as doing it in place, but simple code (if you grok list processing).

If the only reason you're splitting them into pairs is to process them in pairs, you can destructively iterate through the array...

while( my @pair = splice @numbers, 0, 2 ) {
    ...
}

Or you can iterate in pairs in one of the rare valid uses of a 3-part for loop in Perl.

for(
    my $idx = 0;
    my @pair = @numbers[$idx, $idx+1];
    $idx += 2;
)
{
    ...
}

Finally, you can get fancy and use perl5i.

use perl5i::2;
@numbers->foreach( func($first, $second) { ... } );

You can also use List::MoreUtils natatime.

answered Jun 2, 2011 at 6:36

Schwern

167k28 gold badges225 silver badges370 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

cr8ivecodesmith Over a year ago

Wow never knew about these approaches. Anyhow I'll be trying them out and see which ones I find more applicable in my problem. It just seems logical to mark this as my accepted answer. Thanks! :)

MRAB · Accepted Answer · 2011-06-02 02:29:53Z

0

First split on "','" to give you an array, then group the elements as desired.

answered Jun 2, 2011 at 2:29

MRAB

20.7k6 gold badges44 silver badges34 bronze badges

Comments

tofutim · Accepted Answer · 2011-06-02 02:31:31Z

0

I would recommend using regex to retrieve the numbers using '([0-9]+)' and just manually building @foo. Or as @MRAB suggested, split is even more straight-forward. Any reason you are aiming at Regex for this?

answered Jun 2, 2011 at 2:31

tofutim

23.6k20 gold badges91 silver badges159 bronze badges

2 Comments

cr8ivecodesmith Over a year ago

I've tried out @MRAB's approach a while back. However, I just thought that doing this via regex would be more efficient since I would be avoiding looping over the array and then grouping them manually (Normally I would have a string like that with more than a thousand number groups). This thought, of course, is based from my limited knowledge. I'm open for suggestions.

cr8ivecodesmith Over a year ago

Of course I'd still have to loop over the array in my desired output but it would be lesser iterations since it's already pre-grouped.

ysth · Accepted Answer · 2011-06-02 03:22:25Z

0

Tons of different ways. Here's one:

$foo[0] = [];  # assuming you really meant an array of arrays of arrays as you showed
while ($string =~ m/([0-9]++)[^0-9]*+([0-9]++)?/g) {
    push @{ $foo[0] }, [ $1, $2 // () ];
}

(Did you really mean an array containing just one reference to an array of arrayrefs?)

edited Jun 2, 2011 at 3:22

answered Jun 2, 2011 at 3:17

ysth

99.1k6 gold badges126 silver badges219 bronze badges

Comments

Sean · Accepted Answer · 2011-06-02 03:26:50Z

0

This should be a reasonably close fit to your desired behavior:

my @foo;
push @foo, [ $1, $2 // () ] while $string =~ / (\d+) (?: \D+ (\d+) ) ? /gx;

answered Jun 2, 2011 at 3:26

Sean

30k5 gold badges85 silver badges111 bronze badges

Collectives™ on Stack Overflow

Perl Regex: Need help on a way to split string into groups matching a pattern

5 Answers 5

1 Comment

Comments

2 Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

5 Answers 5

1 Comment

Comments

2 Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related