XSLT: Flat XML to Nested HTML List

Question

I'm new to XSLT. I know I need to use xsl:for-each-group, but I can't figure out anything other than a basic list. Would some sort of recursion work better? Any XSLT 1.0 or 2.0 solution would be fine.

Below is the example XML. Note the most important attribute for organizing data into a tree structure is @taxonomy. Other attributes @taxonomyName and @level are provided as optional helper attributes.

<?xml version="1.0" encoding="utf-8"?>
<documents>
    <document level="0" title="Root document test" taxonomy="" taxonomyName="" />
    <document level="1" title="Level one document test" taxonomy="\CategoryI" taxonomyName="CategoryI" />
    <document level="1" title="Level one document test #2" taxonomy="\CategoryII" taxonomyName="CategoryII" />
    <document level="2" title="Level two document test" taxonomy="\CategoryII\SubcategoryA" taxonomyName="SubcategoryA" />
    <document level="2" title="Level two document test #2" taxonomy="\CategoryII\SubcategoryA" taxonomyName="SubcategoryA" />
    <document level="3" title="Level three document test" taxonomy="\CategoryII\SubcategoryA\Microcategory1" taxonomyName="Microcategory1" />
    <document level="2" title="Level two, no level one test" taxonomy="\CategoryIII\SubcategoryZ" taxonomyName="SubcategoryZ" />
</documents>

Here's the expected output. (Please note that indenting is not necessary in the output. I've done it here for readability.)

<ul>
    <li>Root document test</li>
    <li>CategoryI
        <ul>
            <li>Level one document test</li>
        </ul>
    </li>
    <li>CategoryII
        <ul>
            <li>Level one document test #2</li>
            <li>SubcategoryA
                <ul>
                    <li>Level two document test</li>
                    <li>Level two document test #2</li>
                    <li>Microcategory1
                        <ul>
                            <li>Level three document test</li>
                        </ul>
                    </li>
                </ul>
            </li>
        </ul>
    </li>
    <li>CategoryIII
        <ul>
            <li>SubcategoryZ
                <ul>
                    <li>Level two, no subcategory test</li>
                </ul>
            </li>
        </ul>
    </li>
</ul>

Here's the best I can do.

<?xml version="1.0"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:key name="contacts-by-taxonomy" match="document" use="@taxonomy" />
    <xsl:template match="documents">
        <ul>
            <xsl:for-each-group select="document" group-by="@taxonomy">
                <xsl:sort select="@taxonomy" />
                <li>
                    <h3><xsl:value-of select="current-grouping-key()"/></h3>
                    <ul>
                        <xsl:for-each select="current-group()">
                            <li><xsl:value-of select="@title"/></li>
                        </xsl:for-each>
                    </ul>
                </li>
            </xsl:for-each-group>
        </ul>
    </xsl:template>
</xsl:stylesheet>

I'll keep chugging away at it, but would be eternally grateful if someone could throw me a life jacket. Thanks!

I'm trying to figure out what the desired mapping between the input and the expected output is. I'm surprised that "Level one document test #2" never appears in the output. Is that a typo? — LarsH
– LarsH, Commented Jun 3, 2011 at 20:01
Yes, that is a typo. Sorry about that. I have "Level one document test" twice. It looks like the second one should be "Level one document test #2". Thanks for your help. — JustinH
– JustinH, Commented Jun 3, 2011 at 20:16
Can you describe in words the method for determining the output you want given the input? P.S. I fixed that typo for you - I don't know whether you have edit privilege on your own question. — LarsH
– LarsH, Commented Jun 3, 2011 at 20:16
I'm not sure what you mean by "describe the method." I want to take the taxonomy attribute of all the document elements and build a tree out of it. Depending on where I am in the taxonomy "path" I'll do a query for documents that match that taxonomy. — JustinH
– JustinH, Commented Jun 3, 2011 at 20:26
For example, in your expected output, you have the "Root document test" and "CategoryI" at the same <li> nesting level, even though in the input document their taxonomy attribute puts them at different levels (0 and 1). So I'm confused about what the rules are for what nesting level to put an <li> at. — LarsH
– LarsH, Commented Jun 3, 2011 at 20:51

LarsH · Accepted Answer · 2011-06-03 22:35:57Z

5

OK, here's my solution at last. :-) Basically it recurses through the tree, and at each level, it does a for-each-group group-by="the next level of @taxonomy".

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
   <xsl:output method="html" indent="yes" />   

   <xsl:template match="documents">
      <ul>
         <xsl:call-template name="tree-depth-n">
            <xsl:with-param name="population" select="document"/>
            <xsl:with-param name="depth" select="0"/>
            <xsl:with-param name="taxonomy-so-far" select="''"/>
         </xsl:call-template>
      </ul>
   </xsl:template>

   <!-- This template is called with a population that are all descendants
      of the same ancestors up to level n. -->      
   <xsl:template name="tree-depth-n">
      <xsl:param name="depth" required="yes"/>
      <xsl:param name="population" required="yes"/>
      <xsl:param name="taxonomy-so-far" required="yes"/>
      <!-- output a <li> for each document that is a leaf at this level,
      and a <li> for each sub-taxon of this level. --> 
      <xsl:for-each-group select="$population"
                    group-by="string(tokenize(@taxonomy, '\\')[$depth + 2])">
         <xsl:sort select="@taxonomy" />
         <xsl:choose>
            <!-- process documents at this level. -->
            <xsl:when test="current-grouping-key() = ''">
              <xsl:for-each select="current-group()">
                 <li><xsl:value-of select="@title"/></li>
              </xsl:for-each>
            </xsl:when>
            <!-- process subcategories -->
            <xsl:otherwise>
               <li>
                  <h3><xsl:value-of select="current-grouping-key()"/></h3>
                  <ul>
                     <!-- recurse -->
                     <xsl:call-template name="tree-depth-n">
                        <xsl:with-param name="population" select="current-group()"/>
                        <xsl:with-param name="depth" select="$depth + 1"/>
                        <xsl:with-param name="taxonomy-so-far" 
                          select="concat($taxonomy-so-far, '\\', current-grouping-key())"/>
                     </xsl:call-template>                    
                  </ul>
              </li>
            </xsl:otherwise>
         </xsl:choose>
      </xsl:for-each-group>      
   </xsl:template>
</xsl:stylesheet>

With the given input, the output is:

<ul>
   <li>Root document test</li>
   <li>
      <h3>CategoryI</h3>
      <ul>
         <li>Level one document test</li>
      </ul>
   </li>
   <li>
      <h3>CategoryII</h3>
      <ul>
         <li>Level one document test #2</li>
         <li>
            <h3>SubcategoryA</h3>
            <ul>
               <li>Level two document test</li>
               <li>Level two document test #2</li>
               <li>
                  <h3>Microcategory1</h3>
                  <ul>
                     <li>Level three document test</li>
                  </ul>
               </li>
            </ul>
         </li>
      </ul>
   </li>
   <li>
      <h3>CategoryIII</h3>
      <ul>
         <li>
            <h3>SubcategoryZ</h3>
            <ul>
               <li>Level two, no level one test</li>
            </ul>
         </li>
      </ul>
   </li>
</ul>

Which I believe is what you wanted. (I put <h3>s in there as you did in your XSL attempt, for the category names and not for the document titles.)

answered Jun 3, 2011 at 22:35

LarsH

28.1k9 gold badges99 silver badges162 bronze badges

Sign up to request clarification or add additional context in comments.

6 Comments

Emiliano Poggi Over a year ago

+1. Good solution. I'd like to get the same without xsl:for-each-group. This is going to be challenging.

LarsH Over a year ago

@empo, are you trying to get an XSLT 1.0 solution?

Emiliano Poggi Over a year ago

@LarsH: not really, just wondering whether a full templating solution exists (no loops at all).

LarsH Over a year ago

@empo: to my mind, apply-templates is a loop, it's just a loop where the body is specified elsewhere. I guess if you disallowed for-each-group, you'd have to use meunchian grouping.

Emiliano Poggi Over a year ago

@LarsH: I mean, templating (functional programming) versus looping (procedural). Yes meunchian grouping should be, even if the keys here are hard to grasp.

|

Collectives™ on Stack Overflow

XSLT: Flat XML to Nested HTML List

1 Answer 1

6 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

6 Comments

Your Answer

Sign up or log in

Post as a guest

Related