Perl Array handling

Question

I have a global array containing elements such as:

@myarray = ("A","B","C","D","E");

I'm reading a column line by line which has values like:

Row1: A
Row2: Z
Row3: B C
Row4: A B C
Row5: A B C Z
Row6: A C
Row7: E

Problem 1 : If Row1 is read and has "A" which is present in @myarray -> no action required, but in case of Row2 "Z" is not a part of @myarray it should fail with some message.
Some rows have multiple elements, it should check for all, for example row3 "A","B","C" all three are part of @myarray --> no action required, but incase of Row4 it should read "A" , "B","C", then comes "Z" which is not a valid element it should fail with some message.

Please show us your code. Needs minimal example

vkk05
– vkk05

2020-07-19 09:26:48 +00:00
Commented Jul 19, 2020 at 9:26 — vkk05
– vkk05, Commented Jul 19, 2020 at 9:26

ikegami · Accepted Answer · 2020-07-19 11:09:58Z

2

First, create a hash so we can easily and efficiently lookup if a value is valid.

my %ok = map { $_ => 1 } @array;

Then, it's just a question of checking if all the values are in the hash.

while (<>) {
   my ($hdr, $values) = /^([^:]+):\s*(.*)/
      or do {
         warn("Invalid input at \"$ARGV\" line $.\n");
         next;
      };

   my @values = split(' ', $values);
   if ( my @invalid = grep { !$ok{$_} } @values ) {
      warn("Invalid values (@invalid) for $hdr at \"$ARGV\" line $.\n");
      next;
   }
}

answered Jul 19, 2020 at 11:09

ikegami

391k17 gold badges290 silver badges554 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

vkk05 · Accepted Answer · 2020-07-19 11:17:04Z

See if this could help you.

#!/usr/bin/perl

use strict;
use warnings;
use List::Util qw(any);

my @array = qw/A B C D E/;

while(<DATA>){
    chomp($_);
    print "At line -> $_\n";
    my @contents = split(' ', $_);
    
    foreach my $each_element (@contents){
        if (not (any { $_ eq $each_element } @array)) {
            print "$each_element -> Not exists in array\n";
        }
    }
}

__DATA__
A
Z
B C
A B C
A B C Z
A C
E

As suggested by @ikegami, this could also work as per the expectation:

...
my @array = qw/A B C D E/;

my %skip_hash = map { $_ => 1 } @array;

while(<DATA>){
    chomp($_);
    print "At line -> $_\n";
    my @contents = split(' ', $_);
    
    foreach my $each_element (@contents){
        if (not ($skip_hash{$each_element})) {
            print "$each_element -> Not exists in array\n";
        }
    }
}

Collectives™ on Stack Overflow

Perl Array handling

2 Answers 2

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related