How to create GCP instance with public IP with terraform

Question

I need to create a VM instance in gcp with a public IP (instance can randomly pick one for itself) without explicitly defining a one.

So how can I do this?

This is the gcloud command that I can use to achieve this (create a vm instance with automatically assigned public ip)

gcloud compute instances create controller-1 \
    --async \
    --boot-disk-size 200GB \
    --can-ip-forward \
    --image-family ubuntu-2004-lts \
    --image-project ubuntu-os-cloud \
    --machine-type e2-standard-2 \
    --private-network-ip 10.240.0.10 \
    --scopes compute-rw,storage-ro,service-management,service-control,logging-write,monitoring \
    --subnet kubernetes \
    --tags kubernetes-the-hard-way,controller

Above command will create a vm with both internal IP 10.240.0.10 and a Public ip with some randomly picked ip address.

So I want to achieve the same goal with terraform

This is my terraform code. but how can I do this?

resource "google_compute_instance" "controllers" {
  name         = "controller-0"
  machine_type = "e2-standard-2"
  zone         = var.zone

  can_ip_forward = true



  tags = ["kubernetes-the-hard-way", "controller"]
  

  boot_disk {
    initialize_params {
      image = "ubuntu-2004-focal-v20200720"
    }
  }

  network_interface {
    subnetwork = google_compute_subnetwork.kubernetes.name
    network_ip = "10.240.0.10"  // private ip but how to assign a public ip (randomly)  
  }

  service_account {
    scopes = ["compute-rw", "storage-ro", "service-management", "service-control", "logging-write", "monitoring"]
  }
}

divya nayaka · Accepted Answer · 2020-08-14 05:32:46Z

17

An empty access_config block would assign an external ephemeral IP to your instance.

network_interface {
    network = "default"
    access_config {}
}

answered Aug 14, 2020 at 5:32

divya nayaka

2061 silver badge4 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Thomas8 · Accepted Answer · 2021-05-12 02:59:33Z

8

Looks like you need to specify "access_config" under "network_interface" to assign external(public) IP to GCE instance according to this example from terraform.

resource "google_compute_address" "static" {
  name = "ipv4-address"
}

data "google_compute_image" "debian_image" {
  family  = "debian-9"
  project = "debian-cloud"
}

resource "google_compute_instance" "instance_with_ip" {
  name         = "vm-instance"
  machine_type = "f1-micro"
  zone         = "us-central1-a"

  boot_disk {
    initialize_params {
      image = data.google_compute_image.debian_image.self_link
    }
  }

  network_interface {
    network = "default"
    access_config {
      nat_ip = google_compute_address.static.address
    }
  }
}

Google Cloud Platform's Compute Engine Supports two types of external IP addresses:

Static external IP addresses

Ephemeral external IP addresses

edited May 12, 2021 at 2:59

Thomas8

1,1591 gold badge12 silver badges22 bronze badges

answered Aug 14, 2020 at 3:49

Pralove Tandukar

1184 bronze badges

3 Comments

Thomas8 Over a year ago

... a screenshot?

GoForth Over a year ago

It's worth noting that you do pay for a static IP address, around $7.20 a month last I checked. The ephemeral option is free.

JackTheKnife Over a year ago

How to assign nat_ip already reserved IP by the name of that address resource in GCP?

Collectives™ on Stack Overflow

How to create GCP instance with public IP with terraform

2 Answers 2

Comments

3 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

3 Comments

Your Answer

Sign up or log in

Post as a guest

Related