Adding Array to Hash of Arrays without Reference

Question

I'm working with an API to get Information and save it into a file

#!/bin/perl
use strict;
use warnings;
use JSON;
use Data::Dumper;

my %Hash;
my @Array;
my $url = "https://foo/bar"
my $apidata = `/usr/bin/curl -k -u $url`
my $apidatajson = decode_json $apidata;
my $i=0;

foreach(@{ $apidatajson->{category} }){
   @Array=();
   my $Name=$apidatajson->{category}[$i]{Name};
   my $value=$apidatajson->{category}[$i]{Value};
   
   push(@Array,($Name,$value));
   $Hash{$Name}=@Array; # Output 1
   $Hash{$Name}=\@Array; # Output 2

   $i++;

}
print Dumper \%Hash;

Output 1 looks something like this:

$VAR1{
  "FooName2" => 2;
  "FooName" => 2;
};

Output 2 looks something like this:

$VAR1{
  "FooName2" => [
               "FooName2"
               "FooValue2"
              ]
   "FooName" => $VAR1 -> {'FooName2'}
};

Id need it to look like this:

$VAR1 {
   "FooName2" => [
               "FooName2"
               "FooValue2"
                ]   
   "FooName" => [
               "FooName"
               "FooValue"
                ]
}

So essentially what I'm asking is, how can I save the content of the Array in the Hash, without using a Reference, so it doesn't mess up every entry but the last one?

You are missing a } on the line of the foreach. Futhermore, your code does not reproduce the issue you are talking about (probably because you added a my before @Array=() within the loop). Finally, you are using double quotes instead of backticks around curl https:/foo/bar. Next time, please test your code before posting a question. — Dada
– Dada, Commented Aug 17, 2020 at 7:49
(just realized my previous comment sounds a bit harsher that I would have liked): you were right to simplify your code before posting, and we appreciate. Next time, just run it locally after the simplification and before posting ;) Anyway, welcome on StackOverflow. — Dada
– Dada, Commented Aug 17, 2020 at 7:57

Dada · Accepted Answer · 2020-08-17 07:47:46Z

2

The code in your question is not the code you are running. In particular, I suspect that you do not have the line my @Array = () but rather @Array = () (without my).

Thus, $Hash{$Name} = \@Array; takes the reference of the array declared outside of the foreach loop (since there is actually none declared within the loop), which is why both values of your hashtable are the same.

If you declare @Array within your loop, the your code works properly.

Additional notes:

Your seem confused between the "foreach" loop and the C-style for loop. Your loop should be:

 for (@{ $apidatajson->{category}}){
     my @Array;
     my $Name  = $_->{Name};
     my $value = $_->{Value};

     push(@Array,($Name,$value));
     $Hash{$Name} = \@Array;
 }

Or, since you don't really need @Array, simply:

 for (@{ $apidatajson->{category}}){
     my $Name  = $_->{Name};
     my $value = $_->{Value};

     $Hash{$Name} = [$Name, $value];
 }

Or, if you need to keep your $i:

 for my $i (0 .. $#{$apidatajson->{category}}) {
      my $Name  = $apidatajson->{category}[$i]{Name};
      my $value = $apidatajson->{category}[$i]{Value};

      $Hash{$Name} = [$Name, $value];
 }

You don't need to call curl to do an http request. Instead, you can use a Perl module like LWP::Simple:
```
 use LWP::Simple;
 my $apidata = get("https://foo/bar") or die "Failed to get data from API!";
```

answered Aug 17, 2020 at 7:47

Dada

6,7657 gold badges28 silver badges48 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

Silvar Over a year ago

I think you may also be confused with the distinction between for and foreach. Perl doesn't care which name you use for the loop - just what's inside the parens. The names for and foreach are interchangeable either way. Something looking like for (@list) results in a foreach loop and something like foreach (my $i = 0; $i < $n; ++$i) will result in a for loop. The difference is that foreach will implicitly localize a previously declared iteration variable, so it will revert to the value it had outside the loop, once the loop exits.

Dada Over a year ago

@Silvar I am well away that for and foreach are interchangeable. However, saying "you seem confused between for and for" seems less clear than "you seem confused between foreach and c-style for". Furthermore, if you look at the documentation, you'll notice that the terms "foreach" and "C-style for" are used in the same way as they are in my answer.

Dada Over a year ago

@Silvar Furthermore, the remark in my answer about for loops is not about "for vs foreach" but rather about the usefulness of doing my $i = 0; for (@array) { f($array[$i]); $i++ } rather than for (@array) { f($_) }. I'd say that anyone doing the former missed the point of foreach loops.

ceving · Accepted Answer · 2020-08-17 07:41:35Z

1

Try this:

$Hash{$Name}=[$Name, $value];

Square brackets are array references in Perl.

You can not avoid an array reference, if you need it. Your requirements are contradictory.

BTW: what you have created in the second version is a cyclic reference. Probably because of the same variable name in the global and local scope. But I think the output does not belong to your code.

edited Aug 17, 2020 at 7:41

answered Aug 17, 2020 at 7:31

ceving

24.2k15 gold badges120 silver badges201 bronze badges

1 Comment

elgringoloco Over a year ago

yes, its the other way round so "FooName" => $VAR1 -> {'FooName2'}, if you dont mean that then maybe I missed something when simplifying my code, sorry if that is the case.

Collectives™ on Stack Overflow

Adding Array to Hash of Arrays without Reference

2 Answers 2

3 Comments

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

3 Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related