Converting JSON into XML in Dataweave

Question

Input JSON is

[{
    "Master_Job__r": {
        "Customer Contacted__C": "Rupesh",
        "Inspected__C": "",
        "Lost__C": "Fire",
        "Job Start Date__C": "2019-10-25",
        "Work Complete__C": "",
        "Billing Complete__C": ""
    }
}]

Using the DW script mentioned below:-

%dw 2.0
output application/xml
---

    {
        XACTDOC: {
            XACTNET_INFO: {
                CONTROL_POINTS: {
                    (payload map ( payload01 , indexOfPayload01 ) -> {
                        CONTROL_POINT @("type": if(payload01.Master_Job__r."Customer Contacted__C" != "") payload01.Master_Job__r."Customer Contacted__C" else null,
                            "type": if (!isEmpty(payload01.Master_Job__r."Inspected__C")) "" else payload01.Master_Job__r."Inspected__C",  
                            "type": payload01.Master_Job__r.Lost__C , 
                            "type": payload01.Master_Job__r."Job Start Date__C" , 
                            "type": payload01.Master_Job__r."Work Complete__C" ,
                            "type": payload01.Master_Job__r."Billing Complete__C"
                        ): {
                        }
                    })
                }
            }
        }
    }

When Transforming the data below is the result

<?xml version='1.0' encoding='UTF-8'?>
<XACTDOC>
    <XACTNET_INFO>
        <CONTROL_POINTS>
            <CONTROL_POINT type="Rupesh" type="" type="Fire" type="2019-10-25" type="" type=""/>
        </CONTROL_POINTS>
    </XACTNET_INFO>
</XACTDOC>

The second input json value is empty then in output i dont want to display anything but in my output it is displaying as type="" . If the value is present then i need to display.The value is generated dynamically.

Salim Khan · Accepted Answer · 2020-08-23 22:03:34Z

3

You need to wrap your if condition around the key,vlaue pair.

%dw 2.0
output application/xml
---
{
    XACTDOC: {
        XACTNET_INFO: {
            CONTROL_POINTS: {
                (payload map ( payload01 , indexOfPayload01 ) -> {
                    CONTROL_POINT @("type": if(payload01.Master_Job__r."Customer Contacted__C" != "") payload01.Master_Job__r."Customer Contacted__C" else null,
                        ("type": payload01.Master_Job__r."Inspected__C") if payload01.Master_Job__r."Inspected__C" != "" ,  
                        "type": payload01.Master_Job__r.Lost__C , 
                        "type": payload01.Master_Job__r."Job Start Date__C" , 
                        ("type": payload01.Master_Job__r."Work Complete__C") if payload01.Master_Job__r."Work Complete__C" != "",
                        ("type": payload01.Master_Job__r."Billing Complete__C") if payload01.Master_Job__r."Billing Complete__C" != ""
                    ): {
                    }
                })
            }
        }
    }
}

Output:

<?xml version='1.0' encoding='UTF-8'?>
<XACTDOC>
  <XACTNET_INFO>
    <CONTROL_POINTS>
      <CONTROL_POINT type="Rupesh" type="Fire" type="2019-10-25"/>
    </CONTROL_POINTS>
  </XACTNET_INFO>
</XACTDOC>

answered Aug 23, 2020 at 22:03

Salim Khan

4,31313 silver badges15 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

mupiri m Over a year ago

Hi Salim, Thanks for the update but in input { "Master_Job__r": { "Customer Contacted__C": "", "Inspected__C": "", "Lost__C": "hyh", "Job Start Date__C": "", "Work Complete__C": "", "Billing Complete__C": "" } } ] then received output is <?xml version='1.0' encoding='UTF-8'?> <XACTDOC> <XACTNET_INFO> <CONTROL_POINTS> <CONTROL_POINT type="null" type="hyh"/> </CONTROL_POINTS> </XACTNET_INFO> </XACTDOC> In Input Customer Contacted value is Empty we shouldn't get line but in output i received type= null

short stack stevens · Accepted Answer · 2020-08-24 15:02:55Z

2

Alternatively you could also use the mapObject function.

%dw 2.0
output application/xml
---
{
    XACTDOC: {
        XACTNET_INFO: {
            CONTROL_POINTS: {
                (payload map ( payload01 , indexOfPayload01 ) -> {
                    CONTROL_POINT @(
                        (payload01.Master_Job__r mapObject {
                            ("type": $) if(!isEmpty($))
                        })
                    ): {}
                })
            }
        }
    }
}

answered Aug 24, 2020 at 15:02

short stack stevens

6923 silver badges12 bronze badges

Comments

olamiral · Accepted Answer · 2020-08-24 12:50:16Z

Follow the same logic that @Salim Khan used in his answer for each type attribute mapping:

%dw 2.0
output application/xml
---

    {
        XACTDOC: {
            XACTNET_INFO: {
                CONTROL_POINTS: {
                    (payload map ( payload01 , indexOfPayload01 ) -> {
                        CONTROL_POINT @(
                            ("type": payload01.Master_Job__r."Customer Contacted__C") if !isEmpty(payload01.Master_Job__r."Customer Contacted__C"),
                            ("type": payload01.Master_Job__r."Inspected__C") if !isEmpty(payload01.Master_Job__r."Inspected__C"),  
                            ("type": payload01.Master_Job__r.Lost__C) if !isEmpty(payload01.Master_Job__r.Lost__C), 
                            ("type": payload01.Master_Job__r."Job Start Date__C") if (!isEmpty(payload01.Master_Job__r."Job Start Date__C")) , 
                            ("type": payload01.Master_Job__r."Work Complete__C") if (!isEmpty(payload01.Master_Job__r."Work Complete__C")),
                            ("type": payload01.Master_Job__r."Billing Complete__C") if (!isEmpty(payload01.Master_Job__r."Billing Complete__C"))
                        ): {
                        }
                    })
                }
            }
        }
    }

Collectives™ on Stack Overflow

Converting JSON into XML in Dataweave

3 Answers 3

1 Comment

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

1 Comment

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related