How to define a variable being a dictionary with list values in Robot Framework

Question

In one of my testcases I need to define a dictionary, where the keys are string and the values are arrays of strings. How can I do so in Robot Framework?

My first try using a construct as shown below, will not work.

*** Variables ***
&{Dictionary}     A=StringA1  StringA2   
...               B=StringB1   StringB2

Another idea might be to use Evaluate and pass the python expression for a dictionary, but is this the only way how it can done?

*** Variables ***
&{Dictionary}     Evaluate  { "A" : ["StringA1",  "StringA2"], "B": ["StringB1","StringB2"]}

Bence Kaulics · Accepted Answer · 2020-09-23 06:29:09Z

You have a couple more options beside using the Evaluate keyword.

You could use a Python variable file:

DICTIONARY = { "A" : ["StringA1",  "StringA2"], "B": ["StringB1","StringB2"]}

Suite:

*** Settings ***
Variables    VariableFile.py

*** Test Cases ***
Test
    Log    ${DICTIONARY}

You can define your lists separately, and then pass them as scalar variables when defining the dictionary.

*** Variables ***
@{list1}    StringA1    StringA2
@{list2}    StringB1    StringB1
&{Dictionary}    A=${list1}    B=${list2}

*** Test Cases ***
Test
    Log    ${Dictionary}

You can create a user keyword using the Create List and Create Dictionary keywords. You can achieve the same in Python by writing a small library.

*** Test Cases ***
Test
    ${Dictionary}=    Create Dict With List Elements
    Log    ${Dictionary}


*** Keyword ***
Create Dict With List Elements
    ${list1}=    Create List    StringA1    StringA2
    ${list2}=    Create List    StringB1    StringB1
    ${Dictionary}=    Create Dictionary    A=${list1}    B=${list2}
    [return]    ${Dictionary}

SteinOv · Accepted Answer · 2024-03-11 08:11:59Z

1

To add another option to Bence Kaulics answer, you can also use Inline Python evaluation. So for example:

&{Dictionary}    A=${{["StringA1","StringA2"]}}    B=${{["StringB1","StringB2"]}}

answered Mar 11, 2024 at 8:11

SteinOv

113 bronze badges

Collectives™ on Stack Overflow

How to define a variable being a dictionary with list values in Robot Framework

2 Answers 2

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related