Passing array arguments to Perl subroutine

You can't pass arrays to subs (and they can't return them). You can only pass a number of scalars. What you are doing is equivalent to the following:

prueba(1,5,9,1,7,8,9,6,5,6,9);

All of the arguments end up in @array1. What we do is pass references to arrays.

prueba(\@primero,\@segundo);

But that also requires changing the sub. Without change, all of the arguments still end up in @array1. See perlreftut for a start on working with references. You can use

sub prueba{
  my ($array1, $array2)=@_;
  if (scalar(@$array1)<scalar(@$array2)) {
    print "@$array1\n";
  } elsif (scalar(@$array1)>scalar(@$array2)){
    print "@$array2\n";
  }
}

or just

sub prueba {
  my ($array1, $array2) = @_;
  if    (@$array1 < @$array2) { say "@$array1"; }
  elsif (@$array1 > @$array2) { say "@$array2"; }
}

< and > expect a number, so they already impose scalar context. And might as well use say, though that requires use feature qw( say ); (or something like use 5.014; which does the trick as well).

You can use prototypes to make it look like you're passing multiple arrays, and have perl turn them automatically into references:

sub prueba :prototype(\@\@) {
    my ($array1, $array2) = @_;
    if (@$array1 < @$array2) {
        print @$array1,"\n";
    } elsif (@$array1 > @$array2){
        print @$array2,"\n";
    }
}

my @primero=(1,5,9);
my @segundo=(1,7,8,9,6,5,6,9);
prueba(@primero, @segundo);

But read the documentation carefully to understand the cases where the subroutine can be called without enforcing the prototype.

Thanks all I just figured out what I wanted. I found that I can actually pass an array to perl, however maybe I am not explaning mysfel properly.The thing is to load the arrays as follow, inside the subroutine.

my @primero=@{$_[0]};
my @segundo=@{$_[1]};

This means we are using the reference. Ehen running the function, we must write the \ before each input:

prueba(\@primero,\@segundo);