How to apply a function to each columns in kdb?

Question

Let's say I have the following,

q)add2:{[x]:x+2};
q)Bidcols:`Bid1px`Bid2px`Bid3px;
q)table:([]time:9 11;Bid1px:4 5;Bid2px:7 3;Bid3px:6 8);
time Bid1px Bid2px Bid3px
-------------------------
9    4      7      6
11   5      3      8

and I want to apply this add2 function to each cols of the table like the below

q)table:update Bid1px:add2'[Bid1px],Bid2px:add2'[Bid2px],Bid3px:add2'[Bid3px] from table;
time Bid1px Bid2px Bid3px
-------------------------
9    6      9      8
11   7      5      10

My questions are:

Is there a way to do this using Bidcols?
What are the other efficient ways to achieve this?

Thanks in advance.

As my answer to your previous question suggested (stackoverflow.com/a/68919735/3895697), whenever you want to parameterise a select statement you should consider switching to the functional form. — terrylynch
– terrylynch, Commented Aug 30, 2021 at 9:40

user12704155 · Accepted Answer · 2021-08-30 00:16:23Z

3

You can do this using a function select:

q)?[table; (); 0b; `time`Bid1px ! (`time; (each; add2; `Bid1px))]
time Bid1px
-----------
9    6     
11   7

For (1), if you want to do it using Bidcols:

q)?[table; (); 0b; ] (cols table) ! {$[x in Bidcols; (each; add2; x); x]} each cols table
time Bid1px Bid2px Bid3px
-------------------------
9    6      9      8     
11   7      5      10

I'm not sure what you mean for (2)? Are you asking for the most efficient way to do this?

answered Aug 30, 2021 at 0:16

user12704155

Sign up to request clarification or add additional context in comments.

1 Comment

Steve Over a year ago

yes, are there any better ways to do this?

Anton Dovzhenko · Accepted Answer · 2021-08-30 04:06:21Z

3

Functional select/update are most general and flexible approaches. However, in this particular case reassignment works well:

table[Bidcols]: add2 table[Bidcols];

because add2 function already supports vectors.

If add didn't support vectors straightaway, e.g.

add: {[x]: $[x>10;x+2;x+3]}

Following reassignment would work:

table[Bidcols]: (add'') table[Bidcols];

edited Aug 30, 2021 at 4:06

answered Aug 30, 2021 at 1:59

Anton Dovzhenko

2,57913 silver badges16 bronze badges

Comments

Igor Korkhov · Accepted Answer · 2021-09-01 09:12:11Z

0

Another solution:

q)@[table;Bidcols;add2]
time Bid1px Bid2px Bid3px
-------------------------
9    6      9      8
11   7      5      10

or

q)@[`table;Bidcols;add2]

for an in-place update.

answered Sep 1, 2021 at 9:12

Igor Korkhov

8,7201 gold badge28 silver badges32 bronze badges

Collectives™ on Stack Overflow

How to apply a function to each columns in kdb?

3 Answers 3

1 Comment

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

1 Comment

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related