How to create hash of array in Perl

Question

I have a data like this

Group AT1G01040-TAIR-G
        LOC_Os03g02970 69%
Group AT1G01050-TAIR-G
        LOC_Os10g26600 85%
        LOC_Os10g26633 35%
Group AT1G01090-TAIR-G
        LOC_Os04g02900 74%

How can create the data structure that looks like this:

print Dumper \%big;

$VAR = { "Group AT1G01040-TAIR-G" => ['LOC_Os03g02970 69%'],
         "Group AT1G01050-TAIR-G" => ['LOC_Os10g26600 85%','LOC_Os10g26633 35%'],
         "Group AT1G01090-TAIR-G" => ['LOC_Os04g02900 74%']};

This is my attempt, but fail:

my %big;
while ( <> ) {
    chomp;
    my $line = $_;
    my $head = "";
    my @temp;

    if ( $line =~ /^Group/ ) {
        $head = $line;
        $head =~ s/[\r\s]+//g;
        @temp = ();


    }
    elsif ($line =~ /^\t/){
        my $cont = $line;
           $cont =~ s/[\t\r]+//g;
        push @temp, $cont;

        push @{$big{$head}},@temp;
    };

}

why not produce a hash of arrays as hashes? So your datastructure becomes like: Group AT1G01040-TAIR-G" => [{'LOC_Os03g02970' = > 69}] (in case you need to do some calculation with them, or store them in a xml or...?) — dr jerry
– dr jerry, Commented Aug 20, 2011 at 7:39

cjm · Accepted Answer · 2011-08-20 23:41:48Z

2

Here's how I'd do it:

my %big;
my $currentGroup;

while (my $line = <> ) {
    chomp $line;

    if ( $line =~ /^Group/ ) {
        $big{$line} = $currentGroup = [];
    }
    elsif ($line =~ s/^\t+//) {
        push @$currentGroup, $line;
    }
}

You should probably add some additional error checking to this, e.g. an else clause to warn about lines that don't match either regex. Also, check to see if $currentGroup is undef before pushing (in case the first line begins with a tab instead of "Group").

The biggest problem with your original code is that you're declaring and initializing $head and @temp inside the loop, which means they got reset on every line. Variables that need to persist across lines have to be declared outside the loop, as I've done with $currentGroup.

I'm not quite sure what you're intending to accomplish with the s/[\r\s]+//g; bit. \r is included in \s, so that means the same as s/\s+//g; (which would strip all whitespace), but your desired result hash includes whitespace in your keys. If you want to strip trailing whitespace, you need to include an anchor: s/\s+\z//.

edited Aug 20, 2011 at 23:41

answered Aug 20, 2011 at 7:15

cjm

62.2k9 gold badges133 silver badges179 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

dr jerry Over a year ago

I think I would do the same but also make a reference out of %big. ($big->{$line}) It took my Perl masters a lot of time to teach/beat me until I understood them but cant live without them anymore I'm now trying to convince my current colleagues.

Dynamic · Accepted Answer · 2011-08-20 13:45:29Z

2

Well, I don't want to give you an answer, so I'll just tell you to look at:

Well, there ya go :-).

answered Aug 20, 2011 at 13:45

Dynamic

9271 gold badge13 silver badges31 bronze badges

4 Comments

Joel Berger Over a year ago

+1 for perlreftut, one of the most useful docs in all of perldoc!

Dynamic Over a year ago

Thanks @Joel. I found it very useful in learning to use References in Perl.

Joel Berger Over a year ago

That comment got me to thinking about my favorite perldocs and I made a little blog post about some it.

Dynamic Over a year ago

@Joel: Nice blog post! Though I would say you need to read more than just those three Perldocs to learn Perl.

Mat · Accepted Answer · 2011-08-20 07:15:10Z

1

Your pushing arrays to your hash item. You should just be pushing the values. (You don't need @temp at all.)

push @{$big{$head}}, $cont;

Also $head must be declared outside your loop, otherwise it looses its value after each iteration.

answered Aug 20, 2011 at 7:15

Mat

208k41 gold badges407 silver badges423 bronze badges

Collectives™ on Stack Overflow

How to create hash of array in Perl

3 Answers 3

1 Comment

4 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

1 Comment

4 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related