Count number of objects whose attribute are "null" or contain "null"

Question

I have the following JSON. From there I'd like to count how many objects I have which type attribute is either "null" or has an array that contains the value "null". In the following example, the answer would be two. Note that the JSON could also be deeply nested.

{
  "A": {
    "type": "string"
  },
  "B": {
    "type": "null"
  },
  "C": {
    "type": [
      "null",
      "string"
    ]
  }
}

I came up with the following, but obviously this doesn't work since it misses the arrays. Any hints how to solve this?

jq '[..|select(.type?=="null")] | length'

peak · Accepted Answer · 2022-06-03 15:07:46Z

2

This answer focuses on efficiency, straightforwardness, and generality.

In brief, the following jq program produces 2 for the given example.

  def count(s): reduce s as $x (0; .+1);

  def hasValue($value):
    has("type") and 
      (.type | . == $value or (type == "array" and any(. == $value)));

  count(.. | objects | select(hasValue("null")))

Notice that using this approach, it would be easy to count the number of objects having null or "null":

count(.. | objects | select(hasValue("null") or hasValue(null)))

edited Jun 3, 2022 at 15:07

answered Jun 3, 2022 at 12:04

peak

119k21 gold badges185 silver badges218 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

pmf · Accepted Answer · 2022-06-03 07:20:29Z

1

You were almost there. For arrays you could use IN. I also used objects, strings and arrays which are shortcuts to a select of the according types.

jq '[.. | objects.type | select(strings == "null", IN(arrays[]; "null"))] | length'

Demo

On larger structures you could also improve performance by not creating that array of which you would only calculate the length, but by instead just iterating over the matching items (e.g. using reduce) and counting on the go.

jq 'reduce (.. | objects.type | select(strings == "null", IN(arrays[]; "null"))) as $_ (0; .+1)'

Demo

edited Jun 3, 2022 at 7:20

answered Jun 3, 2022 at 7:10

pmf

38.3k3 gold badges31 silver badges41 bronze badges

2 Comments

pmf Over a year ago

@ikegami According to the repository, IN is defined as def IN(src; s): any(src == s; .);, thus purely any. (The lookup table is constructed by INDEX)

ikegami Over a year ago

oh oops, yeah, mixed up IN and INDEX

Collectives™ on Stack Overflow

Count number of objects whose attribute are "null" or contain "null"

2 Answers 2

Comments

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related