what's the best way to get multiple values from a perl array?

Question

For example,

First, I get the dataRecord into an array like this,

  my @dataRecord = split(/\n/);

Next, I filter on the array data record to get the test lines like this,

  @dataRecord = grep(/test_names/,@dataRecord);

Next, I need to get the test names from the test line like this,

   my ($test1_name,$test2_name,$test3_name)  = getTestName(@dataRecord);

   sub getTestName
   {
       my $str = shift @_;
       # testing the str for data and 
       print str,"\n"; # This test point works in that I see the whole test line.
       $str =~ m{/^test1 (.*), test2 (.*), test3 (.)/};
       print $1, "\n"; # This test point does not work. 
       return ($1,$2,$3);
    }

Is there a better way for me to acommplish this task?

what values are you expecting to get back?

evil otto
– evil otto

2011-09-10 00:15:11 +00:00
Commented Sep 10, 2011 at 0:15 — evil otto
– evil otto, Commented Sep 10, 2011 at 0:15

Eric Strom · Accepted Answer · 2011-09-10 01:06:43Z

4

You can chain operations together while reducing the syntax required. This has the advantage of emphasizing the important parts of the program while reducing the syntax noise.

my @test = map m{/^test1 (.*), test2 (.*), test3 (.)/},
           grep /test_names/,
           split /\n/;

# use $test[0], $test[1], $test[2] here

If you are trying to debug a problem, map and grep can take blocks, making it easy to insert error checking code:

my @test = map {
               if (my @match = m{/^test1 (.*), test2 (.*), test3 (.)/}) {
                   @match
               } else {
                   die "regex did not match for: $_"
               }
           } # no comma here
           grep /test_names/,
           split /\n/;

Here are a few different ways to assign from an array that aren't directly related to your question, but are probably useful:

my ($zero, $one,  $two) = @array;
my (undef, $one,  $two) = @array;
my (undef, undef, $two) = @array;  # better written `my $two = $array[2];`

my ($one, $two) = @array[1, 2];    # note that 'array' is prefixed with a @
my ($one, $two) = @array[1 .. 2];  # indicating that you are requesting a list
                                   # in turn, the [subscript] sees list context
my @slice = @array[$start .. $stop];  # which lets you select ranges

To unpack the args to a subroutine:

my ($first, $second, @rest) = @_;

In a method that takes name => value pairs:

my ($self, %pairs) = @_;

edited Sep 10, 2011 at 1:06

answered Sep 10, 2011 at 0:10

Eric Strom

40.2k2 gold badges83 silver badges152 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

Bruc Walker Over a year ago

Thanks Eric, how can I ensure no null values are enter into the @test array?

Eric Strom Over a year ago

What type of null? The value could be undefined, in which case grep defined, .... The value could have no length, grep length, .... The value could be zero, grep $_ != 0, .... Or it could be false, grep $_, .... Add any of these to the processing stack at the point where the erroneous values appear.

Bruc Walker Over a year ago

Thanks again Eric, I am getting Use of uninitialized value $str in pattern match (m//) error, which sounds like the value is not defined. This is a weird error because I thought grep will only capture the filter data you tell it to capture though each data record.

Eric Strom Over a year ago

That's a warning coming from the warnings pragma that is letting you know one of the values you are trying to process is not defined. In your case, it might mean that the regex that you are trying to match against has failed.

Michał Wojciechowski · Accepted Answer · 2011-09-10 00:12:57Z

0

You can get a list of matching subexpressions by using the m// operator in list context, for example by assigning its return value to a list of variables (like you currently do with the subroutine call). So, you can replace the subroutine with a much simpler construct:

my $str = shift @dataRecord;
my ($test1_name, $test2_name, $test3_name) =
    $str =~ m/^test1 (.*), test2 (.*), test3 (.)/;

Or, a for loop if you want to do this for each element of the @dataRecord array:

for my $str (@dataRecord) {
    my ($test1_name, $test2_name, $test3_name) =
        $str =~ m/^test1 (.*), test2 (.*), test3 (.)/;
}

answered Sep 10, 2011 at 0:12

Michał Wojciechowski

2,50015 silver badges9 bronze badges

Collectives™ on Stack Overflow

what's the best way to get multiple values from a perl array?

2 Answers 2

4 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

4 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related