How to pass array of shortstring to a method

Question

I would like to make a procedure that take array of shortstring as argument

procedure f(const a, b: Array of shortstring);

I would like to call this with arrays of known length and shortstrings of known length e.g.

var
  A, B: array[1..2] of string[5];
  C, D: array[1..40] of string[12];
begin
  f(A,B);
  f(C,D);
end;

This result in an compiler error E2008 Incompatible types. Why is that? Can I write a procedure that can take arrays of shortstring (any length of arrays/strings)?

Why use shortstring?

The shortstings are fields in an existing record. There are alot of these record with thousand of shortstrings. In an effort to migrate data from turbo power B-Tree Filer to SQL databases one step is to convert the record to a dataset, and the back to a record, to confirm all fields are converted correctly both directions. I have been using CompareMem on the records to check this, but it does not provide enough information as to which field a conversion error is in. Thus a small program was created, which from the record definition can generate code to compare the two records. It was for this code generator I needed a function to compare shortstrings. It ended up using CompareMem on the shortstrings.

Why do you want to use shortstrings? For the life of me I can't work out when they are useful. — David Heffernan
– David Heffernan, Commented Oct 28, 2011 at 12:46
Just use an array of string. Never mind about declaring the length. Your life will be much easier. — Johan
– Johan, Commented Oct 28, 2011 at 13:03
@David: I found one good use for them a while ago. I was getting difficult-to-trace memory leaks in some heavily recursive tree-based parser code. By changing the symbol object from a string for the symbol name to a ShortString, the name showed up inline in the memory dump in FastMM's FullDebugMode report, making it much easier to find the problem. — Mason Wheeler
– Mason Wheeler, Commented Oct 28, 2011 at 22:10
You can make this much easier on yourself by not using ShortString. Declaring a dynamic array type and using that type will work much more easily; you can find the number if items using Length and the bounds will always be 0 to High(ArrayVar), and pass any argument of that type to your method. — Ken White
– Ken White, Commented Oct 28, 2011 at 23:03
@DavidHeffernan Updated question with why shortstrings are used. — MGH
– MGH, Commented Oct 31, 2011 at 9:17

MishaU · Accepted Answer · 2011-10-28 10:55:02Z

7

A ShortString is 0 to 255 characters long. The length of a ShortString can change dynamically, but memory is a statically allocated 256 bytes, the first byte stores the length of the string, and the remaining 255 bytes are available for characters, whilist string[5] declared in this way allocate only as much memory as the type requires (5 byte + 1 byte for length). you could use type

type
    MyString = string[5];
...
procedure f(const a, b: Array of MyString);
...

var
    A, B: array[1..2] of MyString;
begin
    f(A,B);
end;

edited Oct 28, 2011 at 10:55

answered Oct 28, 2011 at 10:48

MishaU

7186 silver badges15 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

MGH Over a year ago

Thanks for the answer. It only solves the problem for string[5] though. I updated my question to better show what I would like to achieve.

Ondrej Kelle Over a year ago

@MGH That's impossible. array of string[5] and array of string[12] are not compatible types.

Uli Gerhardt · Accepted Answer · 2011-10-31 09:41:46Z

In a similar situation I've used the following:

type
  TOpenArrayOfOpenString = record
  strict private
    FSizeOfString: Integer;
    FpStart: PChar;
    FArrayLength: Integer;
    function GetItemPtr(AIndex: Integer): PShortString;
  public
    constructor Init(var AFirstString: Openstring; AArrayLength: Integer);
    function Equals(const AArray: TOpenArrayOfOpenString): Boolean;

    property SizeOfString: Integer read FSizeOfString;
    property pStart: PChar read FpStart;
    property ArrayLength: Integer read FArrayLength;
    property ItemPtrs[AIndex: Integer]: PShortString read GetItemPtr; default;
  end;

{ TOpenArrayOfOpenString }

constructor TOpenArrayOfOpenString.Init(var AFirstString: Openstring; AArrayLength: Integer);
begin
  FSizeOfString := SizeOf(AFirstString);
  FpStart := @AFirstString[0]; // incl. length byte!
  FArrayLength := AArrayLength;
end;

function TOpenArrayOfOpenString.Equals(const AArray: TOpenArrayOfOpenString): Boolean;
begin
  Result := CompareMem(pStart, AArray.pStart, SizeOfString * ArrayLength);
end;

function TOpenArrayOfOpenString.GetItemPtr(AIndex: Integer): PShortString;
begin
  Result := PShortString(pStart + AIndex * SizeOfString);
end;

You could use it like this:

procedure f(const a: TOpenArrayOfOpenString);
var
  i: Integer;
begin
  for i := 0 to Pred(a.ArrayLength) do
    Writeln(a[i]^);
end;

procedure Test;
var
  A: array[1..2] of string[5];
  C: array[1..40] of string[12];
begin
  f(TOpenArrayOfOpenString.Init(A[1], Length(A)));
  f(TOpenArrayOfOpenString.Init(C[1], Length(C)));
end;

It's not as elegant as a solution built into the language could be and it is a bit hacky as it relies on the fact/hope/... that the strings in the array are laid out contiguously. But it worked for me for some time now.

TheHorse · Accepted Answer · 2011-10-28 10:49:00Z

0

   type
      shortStrings =array[1..2] of string[5];  
    ...
    a,b : shortString;
    ..
    procedure rock(a,b : shortStrings);
    ..

answered Oct 28, 2011 at 10:49

TheHorse

2,8071 gold badge25 silver badges33 bronze badges

Comments

Marco van de Voort · Accepted Answer · 2011-10-28 19:52:31Z

You are combining two different kinds of open array.

First, there is the classic Turbo Pascal "string" (also called "openstring" in Delphi IIRC) which is essentially string[255]. As string[255] is a superset of all shortstrings, the open array aspect simply converts all shortstring types to it.

The "array of xx" syntax is the Delphi (4+?) open array. It is an open array of any type, not just strings, and the syntax to call it is f(nonarrayparam,[arrayelement0,arrayelement1]);

Somehow you seem to mix both syntaxes, and even aggrevate it by adding CONST which sollicits pass by reference and excludes conversions.

I think you assume shortstring has an performance advantage. It has, in some cases. Open array is not one of those cases. Not even in TP :-)

Collectives™ on Stack Overflow

How to pass array of shortstring to a method

4 Answers 4

2 Comments

Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

4 Answers 4

2 Comments

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related