Trying to create VBA macro which will select a column depending on the date

Try this.

Dim COLU As Integer   
COLU = 110   
Range("G6").Select   
Cells(19, COLU).Select

A Workbook SheetActivate: Scroll and Select

ThisWorkbook Module

Private Sub Workbook_SheetActivate(ByVal sh As Object)
    ScrollSelectProject sh
End Sub

Standard Module, e.g. Module1, or ThisWorkbook Module

Sub ScrollSelectProject(ByVal sh As Object)
    
    ' Define constants.
    Dim SHEET_EXCEPTIONS() As Variant: SHEET_EXCEPTIONS = Array( _
        "Sheet2", "Sheet3")
    Const FIRST_DATE_CELL_ADDRESS As String = "H4"
    Const SELECT_ROW As Long = 19
    Const PREVIOUS_MONTHS As Long = 2
    Const SCROLL_TO_ROW As Boolean = False
    
    ' Exclude sheets from the list.
    If IsNumeric(Application.Match(sh.Name, SHEET_EXCEPTIONS, 0)) Then Exit Sub
    
    ' Calculate the 'Select' column.
    Dim SelectColumn As Long:
    With sh.Range(FIRST_DATE_CELL_ADDRESS)
        Dim FirstDate As Date: FirstDate = .Value
        Dim Today1st As Date: Today1st = DateSerial(Year(Date), Month(Date), 1)
        SelectColumn = DateDiff("m", FirstDate, Today1st) - .Column + 1
    End With
    
    ' Calulate the 'Scroll' row and column.
    Dim ScrollRow As Long:
    If SCROLL_TO_ROW Then
        ScrollRow = SELECT_ROW
    Else
        ScrollRow = ActiveWindow.SplitRow + 1
    End If
    Dim ScrollColumn As Long: ScrollColumn = SelectColumn - PREVIOUS_MONTHS
    
    ' Scroll.
    Application.Goto sh.Cells(ScrollRow, ScrollColumn), True
    
    ' Select.
    Application.Goto sh.Cells(SELECT_ROW, SelectColumn)
    
    ' Redraw selection (prevent 'previous selection' also remain visible).
    Application.ScreenUpdating = True
    
End Sub

You want to investigate the worksheet events - in particular WorksheetActivate. You can do this within each sheet. For the purposes of this answer, I will assume that the event handler will call a custom macro.

Public Sub SelectDatedColumns(ws as Worksheet)
    Dim SelectedColumn as Long ' Note: Long, not Integer
    'Assumption: eighth column ('H') represents January 2017
    Dim TodaysDate as Date ' for convenience, to avoid multiple calls to Now()
    TodaysDate = Now()
    SelectedColumn = (Year(TodaysDate) - 2017) * 12 + Month(TodaysDate) + 8 
    ' Note the three magic numbers in the previous statement.
    ws.Columns(SelectedColumn).Select
End Sub

Not tested.

Better coding practice would be to set this as a Function and return a range (ws.Columns(SelectedColumn)) so that the calling routine can decide if to select/display it - and prevent a future race condition where multiple routines are trying to display cells.

Edit: Ran a test based on a comment from OP. The only change to the routine was to parameterise two magic numbers in the code above. The code ran.

Insert the following code into ThisWorkbook module.

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
Dim isProjectSheet As Boolean
' TODO: Code here to validate that it is a project sheet that has been selected. For this example, let us assume it is true.
' TODO: Extend this code to allow for other 'activate' automation.

    isProjectSheet = True ' place holder for the results of validation.
    If isProjectSheet Then
        Dim baseYear As Long
        Dim columnOffset As Long
        baseYear = 2024 '2017
        columnOffset = 8     'Assumption: eighth column ('H') represents January 2017
        SelectDatedColumns Sh, baseYear, columnOffset 'expect 12*1 + 5 + 8 = 25 - "Y"
    End If


End Sub


Private Sub SelectDatedColumns(ws As Worksheet, baseYr As Long, colOffset As Long)
    Dim SelectedColumn As Long ' Note: Long, not Integer
    Dim TodaysDate As Date ' for convenience, to avoid multiple calls to Now()
    TodaysDate = Now()
    SelectedColumn = (Year(TodaysDate) - baseYr) * 12 + Month(TodaysDate) + colOffset
    ' Note the single magic number in the previous statement.
    ws.Columns(SelectedColumn).Select
End Sub