Clojure implementation about five times slower than Java implementation

Question

This is the Java code:

public static FloatBuffer createInterleavedVertexBuffer(AIMesh mesh) {
    FloatBuffer buffer = BufferUtils.createFloatBuffer(mesh.mNumVertices() * 8);
    for (int i = 0; i < mesh.mNumVertices(); i++) {
        var vertex = mesh.mVertices().get(i);
        buffer.put(vertex.x());
        buffer.put(vertex.y());
        buffer.put(vertex.z());

        var normal = mesh.mNormals().get(i);
        buffer.put(normal.x());
        buffer.put(normal.y());
        buffer.put(normal.z());

        var texCoords = mesh.mTextureCoords(0).get(i);
        buffer.put(texCoords.x());
        buffer.put(texCoords.y());
    }
    return buffer.flip();
}

And this is (as far as I can tell) equivalent Clojure code:

(defn create-vertex-buffer
  [mesh]
  (let [buffer (BufferUtils/createFloatBuffer (* (.mNumVertices mesh) 8))]
    (doseq [index (range (.mNumVertices mesh))]
      (let [vertex (.get (.mVertices mesh) index)
            normal (.get (.mNormals mesh) index)
            tex-coords (.get (.mTextureCoords mesh 0) index)]
        (.put buffer (.x vertex))
        (.put buffer (.y vertex))
        (.put buffer (.z vertex))
        (.put buffer (.x normal))
        (.put buffer (.y normal))
        (.put buffer (.z normal))
        (.put buffer (.x tex-coords))
        (.put buffer (.y tex-coords))))
    (.flip buffer)))

However, the Clojure version runs about five times longer than the Java version.

Why is this?

Is there a way to improve the performance of the Clojure version?

There are a few possibilities. Are you compiling with (set! *warn-on-reflection* true)? — Harold
– Harold, Commented Aug 5 at 21:05
Add (set! *warn-on-reflection* true) after the (ns ...) form and reload the namespace in your REPL. You'll see a bunch of reflection warnings coming from this function. Once if resolve them, the function should become close in performance to its Java version. BTW you can use dotimes instead of doseq + range. — Eugene Pakhomov
– Eugene Pakhomov, Commented Aug 5 at 21:06

Gwang-Jin Kim · Accepted Answer · 2025-08-06 16:18:14Z

3

Explicit type hinting might accelerate the execution:

(import [java.nio FloatBuffer]
        [org.lwjgl.assimp AIMesh AIVector3D]
        [org.lwjgl.system BufferUtils])

(defn create-vertex-buffer-optimized
  [^AIMesh mesh]
  (let [num-vertices (.mNumVertices mesh)
        ^FloatBuffer buffer (BufferUtils/createFloatBuffer (* num-vertices 8))]
    (dotimes [index num-vertices]
      (let [^AIVector3D vertex   (.get (.mVertices mesh) index)
            ^AIVector3D normal   (.get (.mNormals mesh) index)
            ^AIVector3D tex-coords (.get (.mTextureCoords mesh 0) index)]
        (.put buffer (.x vertex))
        (.put buffer (.y vertex))
        (.put buffer (.z vertex))
        (.put buffer (.x normal))
        (.put buffer (.y normal))
        (.put buffer (.z normal))
        (.put buffer (.x tex-coords))
        (.put buffer (.y tex-coords))))
    (.flip buffer)))

answered Aug 6 at 16:18

Gwang-Jin Kim

11k20 silver badges39 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

amalloy Aug 6 at 23:01

You shouldn't need the hint on createFloatBuffer, but the others do look necessary since we don't have generics.

Collectives™ on Stack Overflow

Clojure implementation about five times slower than Java implementation

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related