Issue with compiling PL/SQL: invalid relational operator

• Don't manually generate JSON. If one of the values contains a character that should be escaped then your manually generated JSON is not escaping it and will be invalid. Use one of the database's JSON data types (either in SQL or PL/SQL).
• You cannot use INSERTING or DELETING in the SQL scope. You need to move the generation of the op_type value out of the SQL statement and into the PL/SQL.
• ORA_ROWSCN is a pseudo-column and is not valid in an INSERT statement (and you probably don't want to capture it in the table). Just use SYSTIMESTAMP to capture the time of the change.

CREATE OR REPLACE TRIGGER ClientTime
  AFTER INSERT OR UPDATE OR DELETE ON ClientTime
  FOR EACH ROW
DECLARE
  v_pk_json  JSON_OBJECT_T := JSON_OBJECT_T();
  v_changed  JSON_OBJECT_T := JSON_OBJECT_T();
  v_type     VARCHAR2(1);
  v_pk_str   CLOB;
  v_ch_str   CLOB;
BEGIN
  IF INSERTING THEN
    v_type := 'I';
    v_pk_json.put('id', TO_CHAR(:NEW.ID));
    v_changed.put('id', TO_CHAR(:NEW.ID));
    v_changed.put('client', TO_CHAR(:NEW.CLIENT));
    v_changed.put('timestamp', TO_CHAR(:NEW.DATETIME, 'YYYY-MM-DD HH24:MI:SS'));
  ELSIF DELETING THEN
    v_type := 'D';
    v_pk_json.put('id', TO_CHAR(:OLD.ID));
    v_changed.put('id', TO_CHAR(:OLD.ID));
    v_changed.put('client', TO_CHAR(:OLD.CLIENT));
    v_changed.put('timestamp', TO_CHAR(:OLD.DATETIME, 'YYYY-MM-DD HH24:MI:SS'));
  ELSE -- UPDATE: only changed columns
    v_type := 'U';
    v_pk_json.put('id', TO_CHAR(:NEW.ID));

    DECLARE
      v_old_part JSON_OBJECT_T := JSON_OBJECT_T();
      v_new_part JSON_OBJECT_T := JSON_OBJECT_T();
    BEGIN
      IF (:OLD.CLIENT IS NULL AND :NEW.CLIENT IS NOT NULL)
      OR (:OLD.CLIENT IS NOT NULL AND :NEW.CLIENT IS  NULL)
      OR (:OLD.CLIENT <> :NEW.CLIENT)
      THEN
        v_old_part.put('client', TO_CHAR(:OLD.CLIENT));
        v_new_part.put('client', TO_CHAR(:NEW.CLIENT));
      END IF;

      IF (:OLD.DATETIME IS NULL AND :NEW.DATETIME IS NOT NULL)
      OR (:OLD.DATETIME IS NOT NULL AND :NEW.DATETIME IS  NULL)
      OR (:OLD.DATETIME <> :NEW.DATETIME)
      THEN
        v_old_part.put('timestamp', TO_CHAR(:OLD.DATETIME, 'YYYY-MM-DD HH24:MI:SS'));
        v_new_part.put('timestamp', TO_CHAR(:NEW.DATETIME, 'YYYY-MM-DD HH24:MI:SS'));
      END IF;

      v_changed.put('old', v_old_part);
      v_changed.put('new', v_new_part);
    END;
  END IF;

  v_pk_str := v_pk_json.to_string();
  v_ch_str := v_changed.to_string();

  -- insert into audit_log
  INSERT INTO audit_log(
    change_txid,
    change_ts,
    db_user,
    session_id,
    client_host,
    module_name,
    schema_name,
    table_name,
    op_type,
    pk_json,
    changed_columns
  ) VALUES (
    DBMS_TRANSACTION.LOCAL_TRANSACTION_ID,
    SYSTIMESTAMP,
    SYS_CONTEXT('USERENV','SESSION_USER'),
    SYS_CONTEXT('USERENV','SESSIONID'),
    SYS_CONTEXT('USERENV','HOST'),
    SYS_CONTEXT('USERENV','MODULE'),
    'DBNAME',
    'CLIENTTIME',
    v_type,
    v_pk_str,
    v_ch_str
  );
END;
/

Given the tables (note, the scn column has been removed):

CREATE TABLE clienttime (id, client, datetime) AS
SELECT 1, USER, SYSDATE FROM DUAL WHERE 1 = 0;

CREATE TABLE audit_log(
    change_txid,
    change_ts,
    db_user,
    session_id,
    client_host,
    module_name,
    schema_name,
    table_name,
    op_type,
    pk_json,
    changed_columns
  ) AS
SELECT DBMS_TRANSACTION.LOCAL_TRANSACTION_ID,
    SYSTIMESTAMP,
    SYS_CONTEXT('USERENV','SESSION_USER'),
    SYS_CONTEXT('USERENV','SESSIONID'),
    SYS_CONTEXT('USERENV','HOST'),
    SYS_CONTEXT('USERENV','MODULE'),
    'DBNAME',
    'CLIENTTIME',
    'I',
    EMPTY_CLOB(),
    EMPTY_CLOB()
FROM DUAL WHERE 1 = 0

Then if you make the changes:

INSERT INTO clienttime VALUES (1, 'ABC', DATE '1900-01-01');
INSERT INTO clienttime VALUES (2, '"DEF"', SYSDATE);
UPDATE clienttime SET datetime = SYSDATE WHERE id = 1;
COMMIT;
UPDATE clienttime SET datetime = datetime, client = client WHERE id = 2;
DELETE FROM clienttime;

Then the audit-log contains:

• Note: The transaction ID changes after the COMMIT.
• Note 2: When the client is "DEF" then the JSON value is properly escaped "\"DEF\"".

fiddle

  END IF
  -- insert into audit_log

Missing ;

Also you can't use ORA_ROWSCN like this. That's a pseudo-column like rowid.