Extract xml tag name into xml attribute value

Question

The sample xml file is shown below

<a>
<apple color="red"/>
</a>

What should I write in XSLT so that i can get the sample output below ?

<AAA>
<BB bbb="#apple"/> <!-- if possible make it auto close -->
</AAA>

i not sure how to extract it, was thinking about to hard code it eg: <AAA> <BB> **hard code here** </BB> <AAA> — OWLDummy
– OWLDummy, Commented Dec 19, 2011 at 17:08
You may want to have a look at a more generic, completely parameterized solution. :) — Dimitre Novatchev
– Dimitre Novatchev, Commented Dec 19, 2011 at 17:53

Dimitre Novatchev · Accepted Answer · 2011-12-19 17:49:44Z

Here is a generic solution, that accept the name replacements to be made as parameters:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pReps">
  <e oldName="a" newName="AAA"/>
  <e oldName="apple" newName="BB"/>
  <a oldName="color" newName="bbb"/>
 </xsl:param>

 <xsl:variable name="vReps" select=
     "document('')/*/xsl:param[@name='pReps']"/>

 <xsl:template match="*">
     <xsl:element name=
     "{$vReps/e[@oldName = name(current())]/@newName}">
      <xsl:apply-templates select="@*|node()"/>
     </xsl:element>
 </xsl:template>

 <xsl:template match="@*">
  <xsl:attribute name=
  "{$vReps/a[@oldName = name(current())]/@newName}">
   <xsl:value-of select="concat('#', name(..))"/>
  </xsl:attribute>
 </xsl:template>
</xsl:stylesheet>

when this transformation is applied on the provided XML document:

<a>
    <apple color="red"/>
</a>

the wanted, correct result is produced:

<AAA>
   <BB bbb="#apple"/>
</AAA>

Kirill Polishchuk · Accepted Answer · 2011-12-19 17:59:22Z

1

Use name() or local-name() functions:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="/a">
    <AAA>
      <xsl:apply-templates/>
    </AAA>
  </xsl:template>

  <xsl:template match="*">
    <BB bbb="{concat('#', name())}"/>
  </xsl:template>

</xsl:stylesheet>

edited Dec 19, 2011 at 17:59

answered Dec 19, 2011 at 17:09

Kirill Polishchuk

56.4k11 gold badges125 silver badges127 bronze badges

2 Comments

OWLDummy Over a year ago

thanks it works perfectly ~ just because of the {name()} function ~ thanks a lot

Dimitre Novatchev Over a year ago

@KirillPolishchuk: The result of your transformation is different from the OP's wanted result. Please, check and correct. Also, I believe that my generic solution might be interesting to have a look at, as it is completely parameterized vs the hardcoded values in this answer.

Collectives™ on Stack Overflow

Extract xml tag name into xml attribute value

2 Answers 2

Comments

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related