Is file path needed in (Shell Function) VBA?

Question

I have a Matlab-generated executable file, Myfile.exe to call from excel-vba. I learned (Shell Function) is what I need to use.

I don't want to include the whole file path as I do not want to restrict the user to a certain folder in a certain location on each computer.

I have the following code to call the executable, which works fine:

Sub MyExe()
    On Error Resume Next
    Shell ("C:\Users\elwany\Desktop\Myfolder\Myfile.exe")
    If Err <> 0 Then
        MsgBox "Can't start the application.", vbCritical, "Error"
    End If
End Sub

My problem/question is I put the executable + the Excel file with the VBA project in the same folder (Myfolder), and then I modify the code to:

Sub MyExe()
    On Error Resume Next
    Shell ("Myfile.exe")
    If Err <> 0 Then
        MsgBox "Can't start the application.", vbCritical, "Error"
    End If
End Sub

Sometimes it works, sometimes it doesn't!

For example, yesterday I ran the VBA code, it worked. Today I opened the same Excel file, same folder, same everything, it gives "Can't Start Application" error msg!!

Is it not okay to remove the file path even if I have everything in one folder?
Why does it sometimes work, sometimes not?
Is adding the file path absolutely mandatory?

For future reference you can change the current directory with ChDir. so ChrDir ThisWorkbook.Path prior to Shell ("Myfile.exe") would work in this case. — brettdj
– brettdj, Commented Jan 8, 2012 at 2:07

brettdj · Accepted Answer · 2012-01-10 02:35:51Z

2

As you have enquire further about different directories note that you can either

Use ChDir as per my earlier comment to your question

Use Dir instead to validate that myfile.exe is where it needs to be. This method doesn't need error handling to handle the file being missing.

Sub TestB()
Dim strPath As String
strPath = Dir("c:\temp\myfile.exe")
If Len(strPath) > 0 Then
    Shell strPath
Else
    MsgBox "Path doesn't exist"
End If
End Sub


Sub TestA()
On Error Resume Next
'use the host workbook path
' ChDir ThisWorkbook.Path
'set path here
ChDir "C:\temp"
Shell ("Myfile.exe")
If Err <> 0 Then
    MsgBox "Can't start the application.", vbCritical, "Error"
Else
    MsgBox "sucess!", vbOKOnly
End If
End Sub

answered Jan 10, 2012 at 2:35

brettdj

55.9k16 gold badges120 silver badges178 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Alaa Elwany Over a year ago

Brettdj, Thanks a lot for your input! really appreciate it.

chris neilsen · Accepted Answer · 2012-01-08 00:20:30Z

2

When you run a shell like this without a path specified it runs from the Active Directory. What the Active Directory is depends on the OS, not Excel/VBA (unless you explicitly set it)

Try this instead

Sub MyExe()
    On Error Resume Next
    Shell (ThisWorkbook.Path & "\Myfile.exe")
    If Err <> 0 Then
        MsgBox "Can't start the application.", vbCritical, "Error"
    End If
End Sub

answered Jan 8, 2012 at 0:20

chris neilsen

53.3k10 gold badges91 silver badges127 bronze badges

1 Comment

Alaa Elwany Over a year ago

Thanks Chris, I got your point! Your code works. how do we set the active directory, then?

Collectives™ on Stack Overflow

Is file path needed in (Shell Function) VBA?

2 Answers 2

1 Comment

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related