Delphi object casting

Question

I have a main class and several inherited classes that implement a method with the same name, like this:

MainClass = class(TImage)
  //main class methods...
end;

MyClass1 = class(MainClass)
  procedure DoSomething;
end;

MyClass2 = class(MainClass)
  procedure DoSomething;
end;

MyClass3 = class(MainClass)
  procedure DoSomething;
end;

I also have a TList containing pointers to object instances (of several classes). If I want to call the right DoSomething procedure for each class, do I use the following?

if TList[i] is MyClass1 then
  MyClass1(TList[i]).DoSomething
else if TList[i] is MyClass2 then
  MyClass2(TList[i]).DoSomething
else if TList[i] is MyClass3 then
  MyClass3(TList[i]).DoSomething

Is there some casting method that allows me to do this in a few lines of code?

Kornel Kisielewicz · Accepted Answer · 2012-01-31 19:47:51Z

10

Yes, virtual polymorphism :)

MainClass = class(TImage)
  procedure DoSomething; virtual;
end;

MyClass1 = class(MainClass)
  procedure DoSomething; override;
end;

MyClass2 = class(MainClass)
  procedure DoSomething; override;
end;

MyClass3 = class(MainClass)
  procedure DoSomething; override;
end;

And then just:

if TList[i] is MainClass then
  MainClass(TList[i]).DoSomething

If you don't want to do an empty MainClass.DoSomething procedure, you can also mark it virtual; abstract;.

edited Jan 31, 2012 at 19:47

answered Jan 29, 2012 at 9:28

Kornel Kisielewicz

58.1k15 gold badges114 silver badges149 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

GDF Over a year ago

Polymorphism not inheritance... to be specific

mjn Over a year ago

real polymorphism or virtual? ;)

Brad Stowers · Accepted Answer · 2012-01-30 13:03:27Z

4

The virtual inheritance answer is the best for the situation you described where the classes descend from a common base class, but if you have a situation where there is not a common base class between your classes and you need this behavior, you can use interfaces instead to achieve the same result:

  IMainInterface = interface
    ['{0E0624C7-85F5-40AF-ADAC-73B7D79C264E}']
    procedure DoSomething;
  end;

  MyClass = class(TInterfacedObject, IMainInterface)
    procedure DoSomething;
    destructor Destroy; override;
  end;

  MyClass2 = class(TInterfacedObject, IMainInterface)
    procedure DoSomething;
  end;

  MyClass3 = class(TInterfacedObject, IMainInterface)
    procedure DoSomething;
  end;

and then using it would look something like this:

var
  i: integer;
  list: TInterfaceList;
  main: IMainInterface;
begin
  list := TInterfaceList.Create;

  list.Add(MyClass.create);
  list.Add(MyClass2.Create);
  list.Add(MyClass3.Create);

  for i := 0 to 2 do
    if Supports(list[i], IMainInterface, main) then
      main.DoSomething;

  list.Free;

edited Jan 30, 2012 at 13:03

answered Jan 29, 2012 at 15:35

Brad Stowers

3261 silver badge5 bronze badges

3 Comments

Remy Lebeau Over a year ago

Supports() has overloaded versions that return the interface pointer if found, so you do not have to call the as operator, which would redundantly invoke the same interface lookup a second time.

Brad Stowers Over a year ago

Thanks, been too long since I messed with interfaces. I've revised it per your suggestion.

mjn Over a year ago

You can declare list as IInterfaceList, this will add reference counting and save the list.Free (if you leave it as TInterfaceList, do not forget to protect it using try .. finally)

Collectives™ on Stack Overflow

Delphi object casting

2 Answers 2

2 Comments

3 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

3 Comments

Your Answer

Sign up or log in

Post as a guest

Related