Writing VB.NET Windows Forms Application using CodeDom

Question

How can you write a VB.NET Windows Forms Application via CodeDom?

I have tried everything, the closest i got to it is the code below, which first of all shows command prompt window which is not good, and then shows the form for like a second and everything disappears. Is there another proper way to do it? An example is greatly appreciated.

Public Module MyApp
    Public Sub main()
        Dim NewForm As New System.Windows.Forms.Form
        NewForm.Name = "Form1"
        NewForm.Text = "Form1"
        NewForm.Width = 300
        NewForm.Height = 300
        NewForm.FormBorderStyle = Windows.Forms.FormBorderStyle.FixedSingle
        NewForm.ControlBox = True
        NewForm.MaximizeBox = False
        NewForm.MinimizeBox = True
        NewForm.Show()
    End Sub
End Module

You might want to save yourself some headache and use Visual Studio Visual Basic Express 2010 rather than notepad. microsoft.com/visualstudio/en-us/products/2010-editions/… — mellodev
– mellodev, Commented Mar 24, 2012 at 3:17
@shanabus, i just don't seem to be getting how CodeDom works to compile the code within my application, thought of doing the notepad thing as an alternative solution. — NetInfo
– NetInfo, Commented Mar 24, 2012 at 4:54
@mello702, thanks for the suggestion, i already am using that though. — NetInfo
– NetInfo, Commented Mar 24, 2012 at 4:56

Hans Passant · Accepted Answer · 2012-03-24 13:48:16Z

5

It doesn't work because you are not calling Application.Run(). Nothing is stopping the main thread without it, it exits and that's the end of the program and the form. NewForm.ShowDialog() is another cheap fix.

The proper incantations are:

Imports System.Windows.Forms

Public Module MyApp
    Public Sub Main()
        Application.EnableVisualStyles()
        Application.SetCompatibleTextRenderingDefault(False)
        Dim NewForm As New Form
        '' Set properties
        ''...
        Application.Run(NewForm)
    End Sub
End Module

To stop the console window from showing, you'll need to change the EXE type. Project + Properties, Application tab, change the "Application type" setting from Console Application to Windows Forms Application. For CodeDom you need to set the CompilerOptions to specify the /target.

edited Mar 24, 2012 at 13:48

answered Mar 24, 2012 at 11:02

Hans Passant

946k151 gold badges1.8k silver badges2.6k bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Cody Gray Over a year ago

I've read this twice, and still can't figure out why it was downvoted. Maybe because you didn't provide a thorough implementation of the message loop or other largely irrelevant information for a VB.NET programmer that just wants to get his app to run? +1 from me.

Gabe · Accepted Answer · 2012-03-24 11:49:40Z

3

To create a Windows app (as opposed to a console app), you have to specify .CompilerOptions = "/target:winexe" in the CompilerParameters that you pass to the compiler.

answered Mar 24, 2012 at 11:49

Gabe

87.1k13 gold badges144 silver badges238 bronze badges

1 Comment

NetInfo Over a year ago

After a lot of searching online, i made some progress with that, but when i set CompilerOptions = "/target:winexe", it says Sub Main was not found.

NetInfo · Accepted Answer · 2012-03-29 15:55:22Z

After alot of research online, i have came to the following conclusion which seems to be working just fine. Thanks to everybody for any input on this subject.

First of all open a new project add the following code to a button. This code compiles the code that you write in the text file that you will create in the next step.

  Private Sub CompilerButton_Click(sender As System.Object, e As System.EventArgs) Handles CompilerButton.Click
        Dim objCodeCompiler As System.CodeDom.Compiler.ICodeCompiler = New VBCodeProvider().CreateCompiler() ' We create object of the compiler

        Dim objCompilerParameters As New System.CodeDom.Compiler.CompilerParameters()
        ' Add reference
        objCompilerParameters.ReferencedAssemblies.Add("System.dll")
        objCompilerParameters.ReferencedAssemblies.Add("System.Windows.Forms.dll")
        objCompilerParameters.ReferencedAssemblies.Add("Microsoft.VisualBasic.dll")

        'Compile in memory
        Dim Output1 As String = "OutputApp"
        objCompilerParameters.GenerateExecutable = True
        objCompilerParameters.OutputAssembly = Output1
        objCompilerParameters.CompilerOptions = "/target:winexe"

        Dim strCode As String = My.Resources.TextFile1.ToString
        Dim objCompileResults As System.CodeDom.Compiler.CompilerResults = _
        objCodeCompiler.CompileAssemblyFromSource(objCompilerParameters, strCode)

        If objCompileResults.Errors.HasErrors Then
            ' If an error occurs
            MsgBox("Error: Line>" & objCompileResults.Errors(0).Line.ToString & ", " & _
            objCompileResults.Errors(0).ErrorText)
            Exit Sub
        End If

    End Sub

And then in the projects resources add a text file and add the following code to it. This code is your application that you want to compile to a standalone EXE. And you can change it to the way you want.

Option Strict On
Imports System
Imports System.Windows.Forms
Imports System.Windows.Forms.Form
Imports Microsoft.VisualBasic

Namespace MyApp
    Public Class EntryPoint
        Public Shared Sub Main(args As [String]())
            Dim FrmMain As New Form1
            System.Windows.Forms.Application.Run(FrmMain)
        End Sub
    End Class
    Public Class Form1
        Inherits System.Windows.Forms.Form
        Private WithEvents Button1 As New Button
        Sub New()
            Application.EnableVisualStyles()
            Me.Text = "Form1"
            Button1.Text = "Click Me!"
            Button1.Top = 100
            Button1.Left = 100
            Me.Controls.Add(Button1)
        End Sub
        Private Sub Button1_Click(Sender As Object, E As EventArgs) Handles Button1.Click
            MsgBox("You Clicked Me!")
        End Sub
    End Class
End Namespace

If you have done everything above, after you click compile it should create a standalone EXE in the projects \bin\Debug under the name OutputApp.

Again thanks to everybody. Hope the code above is useful to anyone who is trying to do the same thing.

Collectives™ on Stack Overflow

Writing VB.NET Windows Forms Application using CodeDom

3 Answers 3

1 Comment

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

1 Comment

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related