Modifying array in subroutine

Question

I've got some code that doesn't work the way I expect, and I'd appreciate some help figuring out how to get it working the way I DO expect.

I'd like to use a subroutine to modify an input array. I figured that if I passed in a reference to the array, any changes I made to it would be reflected in the caller's version, too. But it apparently doesn't work that way.


my @test_array = qw (zero one two three);

shift_array(\@test_array);
print "POST SUBROUTINE: $test_array[0]\n";

sub shift_array {
    my @array = @{(shift)};
    shift @array;
    print "AFTER SHIFT IN SUB: $array[0]\n";
}

This prints:

AFTER SHIFT IN SUB: one
POST SUBROUTINE: zero

I expected it to print one both times.

So my question is two-fold:

1) Why isn't it behaving the way I think it should? Does passing a reference to an array create a copy of the array?

2) How do I get the behavior I WAS expecting? How do I I get a subroutine to slide one or more elements off of the front of caller's copy of an input array?

Thanks in advance for any insight you can offer.

Cfreak · Accepted Answer · 2012-04-03 16:24:45Z

11

Because my @array is a new array that you assigned the dereferenced original array to. It's a copy.

Instead do this:

sub shift_array {
    my $array = shift;
    shift( @$array );
}

Edit: I originally said dereferencing it creates the problem but using @$array is still dereferencing it. As @mob pointed out, assigning the variable is what creates the new array instead of updating the existing reference.

edited Apr 3, 2012 at 16:24

answered Apr 3, 2012 at 14:56

Cfreak

19.4k6 gold badges52 silver badges64 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

BlairHippo Over a year ago

Wow. That's a nuance I did not understand. Thanks!

mirod Over a year ago

note that with perl 5.14+ you can write shift $array in the sub and the de-referencing happens automagically.

Dave Cross · Accepted Answer · 2012-04-04 08:58:42Z

1

This is one of the (tiny number) of cases where Perl prototypes are useful.

#!/usr/bin/perl

use strict;
use warnings;

# Prototype forces the first argument to be a reference to an array    
sub shift_array (\@) {
  my $array = shift;
  shift(@$array);
  print "AFTER SHIFT IN SUB: @$array[0]\n";
}

my @test_array = qw (zero one two three);

shift_array(@test_array);
print "POST SUBROUTINE: $test_array[0]\n";

answered Apr 4, 2012 at 8:58

Dave Cross

69.5k3 gold badges55 silver badges101 bronze badges

Comments

dawg · Accepted Answer · 2017-01-21 06:32:08Z

1

I prefer to be more consistent in the use of array references to minimize ambiguity:

#!/usr/bin/perl
use strict;
use warnings;

my @test_array = qw (zero one two three);

shift_array(\@test_array);
print "POST SUBROUTINE: $test_array[0]\n";

sub shift_array {
    my $ref = shift;
    shift @$ref;
    print "AFTER SHIFT IN SUB: ${$ref}[0]\n";
}

answered Jan 21, 2017 at 6:32

dawg

105k24 gold badges142 silver badges217 bronze badges

Collectives™ on Stack Overflow

Modifying array in subroutine

3 Answers 3

2 Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

2 Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related