Get tag name/attribute name in XML using XSLT

Question

What's the way to get a tag name and attribute name in XML?

If I have a XML file like this:

<a>
<apple color="red"/>
<banana color="yellow"/>
<sugar taste="sweet"/>
<cat size="small"/>
</a>

And part of my XSLT file is as below:

<xsl:element name="AAA">
<???>
</xsl:element>

So what should I write in the ??? part so I can get the output like this:

For tag name:

<AAA>apple</AAA>
<AAA>banana</AAA>
<AAA>sugar</AAA>
<AAA>cat</AAA>

For attribute name:

<AAA>color</AAA>
<AAA>color</AAA>
<AAA>taste</AAA>
<AAA>size</AAA>

Can you show us what you've tried so far? And for the record, your example is not a valid XML file. — larsks
– larsks, Commented Dec 15, 2011 at 15:14
Is that the entire XML document? It's not well-formed. Can you show more context? — Wayne
– Wayne, Commented Dec 15, 2011 at 15:15

Lukas Eder · Accepted Answer · 2011-12-16 10:36:07Z

16

Tag name:

<xsl:value-of select="name(.)"/>

Attribute name of the first (!) attribute. If you have more attributes, you'd have to choose a different approach

<xsl:value-of select="name(@*[1])"/>

Both expressions would then be used in a template matching your input elements. e.g.

<xsl:template match="*">
  <xsl:element name="AAA">
    <!-- ... -->
  </xsl:element>
</xsl:template>

edited Dec 16, 2011 at 10:36

answered Dec 15, 2011 at 15:19

Lukas Eder

223k138 gold badges731 silver badges1.6k bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Dimitre Novatchev Over a year ago

@_Lucas Eder: <xsl:template match="//*"> can be written properly as: <xsl:template match="*"> . It is meaningless for a match expression to be absolute and in very few cases it consists of more than one location step.

Wayne · Accepted Answer · 2011-12-15 15:29:13Z

Output the name of an element or attribute using one of name() or local-name():

<xsl:value-of select="name()"/>
<xsl:value-of select="local-name()"/>

Assume this document:

<root>
    <apple color="red"/>
    <banana color="yellow"/>
    <sugar taste="sweet"/>
    <cat size="small"/>
</root>

Then this stylesheet:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
    <xsl:template match="/">
        <root>
            <xsl:apply-templates select="/*/*"/>
            <xsl:apply-templates select="/*/*/@*"/>
        </root>
    </xsl:template>
    <xsl:template match="*|@*">
        <AAA><xsl:value-of select="local-name()"/></AAA>
    </xsl:template>
</xsl:stylesheet>

Produces:

<root>
   <AAA>apple</AAA>
   <AAA>banana</AAA>
   <AAA>sugar</AAA>
   <AAA>cat</AAA>
   <AAA>color</AAA>
   <AAA>color</AAA>
   <AAA>taste</AAA>
   <AAA>size</AAA>
</root>

Notice that both elements and attributes are handled by the same template.

Dimitre Novatchev · Accepted Answer · 2011-12-15 15:31:43Z

This is probably one of the shortest solutions:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="*/*|@*">
  <AAA>
   <xsl:value-of select="name()"/>
  </AAA>
   <xsl:apply-templates select="@*"/>
 </xsl:template>
</xsl:stylesheet>

when this transformation is applied on the following XML document (your fragment wrapped into a top element):

<things>
    <apple color="red"/>
    <banana color="yellow"/>
    <sugar taste="sweet"/>
    <cat size="small"/>
</things>

the wanted, correct result is produced:

<AAA>apple</AAA>
<AAA>color</AAA>
<AAA>banana</AAA>
<AAA>color</AAA>
<AAA>sugar</AAA>
<AAA>taste</AAA>
<AAA>cat</AAA>
<AAA>size</AAA>

Collectives™ on Stack Overflow

Get tag name/attribute name in XML using XSLT

3 Answers 3

1 Comment

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

1 Comment

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related