Modifying a PHP file from a Bash script

The way I solved this problem was by separating my file into sections that were encapsulated by . The script kept track of the 'context' it was currently in - by default set to html but switching to php when it hit those tags. An operation (not necessarily a regex) then performs on that section, which is then appended to the output buffer. When the file is completely processed the output buffer is written back into the file.

I attempted to do this with sed, but I faced the problem of not being able to control where newlines would be printed. The context based logic was also hardcoded meaning it would be tedious to add in a new context, like ASP.NET support for example. My current solution is written in Perl and mitigates both problems, although I am having a bit of trouble getting my regex to actually do something, but this might just be me coding my regex incorrectly.

Script is as follows:

#!/usr/bin/perl -w

use strict;

#Prototypes
sub readFile(;\$);
sub writeFile($);

#Constants
my $file;
my $outputBuffer;
my $holdBuffer;
# Regexes should have s and g modifiers
# Pattern is in $_
my %contexts = (
    html => {
        operation => ''
    },
    php => {
        openTag => '<\?php |<\? ', closeTag => '\?>', operation => ''
    },
    js => {
        openTag => '<script>', closeTag => '<\/script>', operation => ''
    }
);
my $currentContext = 'html';
my $combinedOpenTags;

#Initialisation
unshift(@ARGV, '-') unless @ARGV;
foreach my $key (keys %contexts) {
    if($contexts{$key}{openTag}) {
        if($combinedOpenTags) {
            $combinedOpenTags .= "|".$contexts{$key}{openTag};
        } else {
            $combinedOpenTags = $contexts{$key}{openTag};
        }
    }
}

#Main loop
while(readFile($holdBuffer)) {
    $outputBuffer = '';
    while($holdBuffer) {
        $currentContext = "html";
        foreach my $key (keys %contexts) {
            if(!$contexts{$key}{openTag}) {
                next;
            }
            if($holdBuffer =~ /\A($contexts{$key}{openTag})/) {
                $currentContext = $key;
                last;
            }
        }
        if($currentContext eq "html") {
            $holdBuffer =~ s/\A(.*?)($combinedOpenTags|\z)/$2/s;
            $_ = $1;
        } else {
            $holdBuffer =~ s/\A(.*?$contexts{$currentContext}{closeTag}|\z)//s;
            $_ = $1;
        }
        eval($contexts{$currentContext}{operation});
        $outputBuffer .= $_;
    }
    writeFile($outputBuffer);
}

# readFile: read file into $_
sub readFile(;\$) {
    my $argref = @_ ? shift() : \$_;
    return 0 unless @ARGV;
    $file = shift(@ARGV);
    open(WORKFILE, "<$file") || die("$0: can't open $file for reading ($!)\n");
    local $/;
    $$argref = <WORKFILE>;
    close(WORKFILE);
    return 1;
}

# writeFile: write $_[0] to file
sub writeFile($) {
    open(WORKFILE, ">$file") || die("$0: can't open $file for writing ($!)\n");
    print WORKFILE $_[0];
    close(WORKFILE);
}

I hope that this can be used and modified by others to suit their needs.