Transform data to array with Perl

Question

How do I transform my data to an array with Perl?

Here is my data:

my $data =
  "203.174.38.128203.174.38.129203.174.38.1" .
  "30203.174.38.131203.174.38.132203.174.38" .
  ".133203.174.38.134173.174.38.135203.174." .
  "38.136203.174.38.137203.174.38.142";

And I want to transform it to be array like this

my @array= (
  "203.174.38.128",
  "203.174.38.129",
  "203.174.38.130",
  "203.174.38.131",
  "203.174.38.132",
  "203.174.38.133",
  "203.174.38.134",
  "173.174.38.135",
  "203.174.38.136",
  "203.174.38.137",
  "203.174.38.142"
);

Anyone know how to do that with Perl?

Generally speaking, you can't. How are you supposed to split 1.1.1.111.2.2.2 for instance? 1.1.1.1 and 11.2.2.2 or 1.1.1.11 and 1.2.2.2? — Mat
– Mat, Commented Nov 3, 2012 at 17:06
Obviously there are no seperators after each quadrupel. So you need some additional assumption, e.g. that the first and last numbers of the resulting quadrupels must always be 3-digit numbers, or something similar. — Curd
– Curd, Commented Nov 3, 2012 at 17:09

raina77ow · Accepted Answer · 2012-11-03 17:30:32Z

1

If the first part of IP logged is always 203, it's kinda easy:

my @arr = split /(?<=\d)(?=203\.)/, $data;

In the example given it's not, but the first part is always 3-digit, and the second part is always 174, so it's enough to do...

my @arr = split /(?<=\d)(?=\d{3}\.174\.)/, $data;

... to get the correct result.

But please understand that it's close to impossible to give a more generic (and bulletproof) solution here - when these 'marker' parts are... too dynamic. For example, take this string...

11.11.11.22222.11.11.11

The question is, where to split it? Should it be 11.11.11.22; 222.11.11.11? Or 11.11.11.222; 22.11.11.11? Both are quite valid IPs, if you ask me. And it could get even worse, with trying to split '2222' part (can be '2; 222', '22; 22' and even '222; 2').

You can, for example, make a rule: "split each sequence of > 3 digits followed by a dot sign so that the second part of this split would always start from 3 digits":

my @arr = split /(?<=\d)(?=\d{3}\.)/, $data;

... but this will obviously fail to work properly in the ambiguous cases mentioned earlier IF there are IPs with two- or even one-digit first octet in your datastring.

edited Nov 3, 2012 at 17:30

answered Nov 3, 2012 at 17:06

raina77ow

107k16 gold badges205 silver badges240 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

Borodin Over a year ago

This doesn't appear to be a solution. And one of the IPs in the example starts with 173.

raina77ow Over a year ago

@Borodin You're better than me at reading minds, I remember that. ) But why do you think the third snippet is not good enough for the OP? I checked your solution, and while I do agree that building an IP sub-pattern might help, it won't make the code bulletproof for those '2222' cases.

Borodin Over a year ago

I assume that close paren was supposed to be a smiley so I shall take that in good humour, but I'm not sure I know what you mean! You really need that last section highlighting as your answer, but it worries me because of what it will do with stuff like 1.1.1.25525.1.1.1. That isn't ambiguous yet your statement gives 1.1.1.25 and 525.1.1.1

raina77ow Over a year ago

@Borodin My point is that if regex can't be made 100% correct, it'll be wasteful to design for that extra 1% in 99% - especially if you don't know whether it's really 1%, or 0.001%, or 99% itself. I just follow the advice of Friedl's book: with regexes, we often have to balance the efforts against needs. And while I agree that the 3rd snippet is the closest (to the correct answer) here, I just tried to show how regexes are usually built by me - from specific cases first, then, through understanding of common cases, to more generic (and useful) ones.

Borodin · Accepted Answer · 2012-11-04 00:05:40Z

If you write a regex that will match any valid value for one of the numbers in the quartet then you can just search for them all and recombine them in sets of four. This

/2[0-5][0-5]|1\d\d|[1-9]\d|\d/

matches 200-255 or 100-199 or 10-99 or 0-9, and a program to use it is shown below.

There is no way to know which option to take if there is more than one way to split the string, and this solution assigns the longest value to the first of the two ip addresses. For instance, 1.1.1.1234.1.1.1 will split as 1.1.1.123 and 4.1.1.1

use strict;
use warnings;

use feature 'say';

my $data =
  "203.174.38.128203.174.38.129203.174.38.1" .
  "30203.174.38.131203.174.38.132203.174.38" .
  ".133203.174.38.134173.174.38.135203.174." .
  "38.136203.174.38.137203.174.38.142";

my $byte = qr/2[0-5][0-5]|1\d\d|\d\d|\d/;

my @bytes = $data =~ /($byte)/g;
my @addresses;
push @addresses, join('.', splice(@bytes, 0, 4)) while @bytes;

say for @addresses;

output

203.174.38.128
203.174.38.129
203.174.38.130
203.174.38.131
203.174.38.132
203.174.38.133
203.174.38.134
173.174.38.135
203.174.38.136
203.174.38.137
203.174.38.142

Axeman · Accepted Answer · 2012-11-03 18:29:38Z

0

Using your sample, it looks like you have 3 digits for the first and last node. That would prompt using this pattern:

/(\d{3}\.\d{1,3}\.\d{1,3}\.\d{3})/

Add that with a /g switch and it will pull every one.

However, if you have a larger and divergent set of data than what you show for your sample, somebody should have separated the ips before dumping them into this string. If they are separate data points, they should have some separation.

answered Nov 3, 2012 at 18:29

Axeman

29.9k2 gold badges50 silver badges104 bronze badges

Collectives™ on Stack Overflow

Transform data to array with Perl

3 Answers 3

4 Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

4 Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related